stata odbc sqlfile

Question

我正在尝试加载数据从数据库(无论是MS Access或SQL server)使用odbc sqlfile，它似乎代码正在运行与任何错误，但我没有得到数据。我使用下面的代码odbc sqlfile("sqlcode.sql"),dsn("mysqlodbcdata")。请注意，sqlcode.sql只包含带有SELECT的sql语句。问题是，使用odbc load,exec(sqlstmt) dsn("mysqlodbcdata")提供数据的是相同的sql代码。有人能建议我如何使用odbc sqlfile导入数据吗？这会对我有很大的帮助。

谢谢你，Joy

Answer 1

sqlfile不加载任何数据。它只是执行(并在指定just选项时显示结果)，而不将任何数据加载到Stata中。这有点违反直觉，但却是真的。原因在用于odbc命令的pdf/dead tree手动条目中有一些晦涩难懂的解释。

这里有一个更有用的答案。假设您有一个名为sqlcode.sql的SQL文件。你可以在Stata中打开它(只要它不是太长，太长取决于你的Stata风格)。基本上，-file逐行读取代码，并将结果存储在名为exec的本地宏中。然后将该宏作为参数传递给-odbc加载命令：

已更新代码以处理某些双引号问题

将以下代码剪切并粘贴到一个名为loadsql.ado的文件中，您应该将该文件放在Stata可以看到它的目录中(如~/ado/personal)。您可以使用-adopath命令找到这样的目录。

program define loadsql
*! Load the output of an SQL file into Stata, version 1.3 (dvmaster@gmail.com)
version 14.1
syntax using/, DSN(string) [User(string) Password(string) CLEAR NOQuote LOWercase SQLshow ALLSTRing DATESTRing]

#delimit;
tempname mysqlfile exec line;

file open `mysqlfile' using `"`using'"', read text;
file read `mysqlfile' `line';

while r(eof)==0 {;
    local `exec' `"``exec'' ``line''"';
    file read `mysqlfile' `line';
};

file close `mysqlfile';


odbc load, exec(`"``exec''"') dsn(`"`dsn'"') user(`"`user'"') password(`"`password'"') `clear' `noquote' `lowercase' `sqlshow' `allstring' `datestring';

end;

/*全部完成！*/

Stata中的语法是

loadsql using "./sqlfile.sql", dsn("mysqlodbcdata") 

您还可以添加所有其他odbc加载选项，比如clear。显然，您需要更改文件路径和odbc参数以反映您的设置。这段代码应该和sqlfile.sql(“sqlfile.sql”)，dsn(“-odbc”)做同样的事情--再加上实际加载数据。

我还添加了指定DB凭证的功能，如下所示：

loadsql using "./sqlfile.sql", dsn("mysqlodbcdata") user("user_name") password("not12345") 

Answer 2

对于"--XYZ“样式的注释，执行如下操作(假设SQL代码中没有"--”)：

if strpos(`"``line''"', "--") > 0 {;
    local `line' = substr(`"``line''"', 1, strpos(`"``line''"', "--")-1);
    };

我不得不把这个作为答案，否则格式化就会一团糟，但它显然是指Dimitriy的代码。(您还可以定义一个包含"--“字符串位置的本地宏，以使您的代码更简洁。)