在没有视图的FW1中仅使用控制器

Question

我有一个Ajax请求，它将一些数据发送到一个页面，并根据数据是否被保存来期望返回一个真值或假值。在我的控制器中，我执行所有操作，并将内容设置为true或false值。我真的不想创建一个只输出1个变量的视图，所以我想知道是否有一种方法可以让我不必使用视图而只使用控制器来输出简单的字符串。

Answer 1

我相信你不能完全禁用视图，但有一个非常简单的变通办法:你可以创建一个视图并将其用于许多操作。

假设我们已经创建了视图views/main/ajax.cfm，其中可能包含什么内容？显然，最简单的方法是：

<cfoutput>#HTMLEditFormat(rc.response)#</cfoutput>

就我个人而言，我喜欢返回JSON，它允许我有status字段，如果需要的话，加上数据。这样，我的视图如下所示：

<cfheader name="Content-Type" value="application/json" />
<cfoutput>#SerializeJSON(rc.response)#</cfoutput>

无论如何，在我们的行动中，我们需要这样做：

// prevent displaying the layout
request.layout = false;

// force special view
variables.fw.setView("main.ajax");

// init response (according to the choice made earlier)
rc.response["status"] = "OK";
rc.response = "";

对于这一点还有一个问题。有时，您不希望直接访问AJAX页面(如在浏览器中打开)，或者反之亦然，希望在访问时进行一些调试。

在CFWheels框架中有一个很酷的助手isAjax，它很容易移植到FW/1。它可以像向控制器添加这样的方法一样简单：

/*
* Check if request is performed via AJAX
*/
private boolean function isAjax() {

    return (cgi.HTTP_X_REQUESTED_WITH EQ "XMLHTTPRequest");

}

实际上，上面设置代码也是我的应用程序中的助手方法：

/*
* Set up for AJAX response
*/
private struct function setAjax() {

    // prevent displaying the layout
    request.layout = false;

    // force special view
    variables.fw.setView("main.ajax");

    local.response["status"] = "OK";

    return local.response;

}

因此，在我的动作代码中，整个检查看起来像这样，非常简洁和方便：

if (isAjax()) {
    rc.response = setAjax();
}
else {
    return showNotFound();
}

希望这能有所帮助。

Answer 2

您不能直接从Controller输出:它的工作只是调用Model并将数据传递给View，因此您需要一个视图模板来进行输出。

但是，通过使用框架的setView()方法，您可以避免为每个控制器方法创建单独的视图。这允许您覆盖约定，并将单个视图应用于多个控制器方法。因此，您可以设置一个通用的"ajax view“，然后使用它从任何控制器输出数据：

views/main/ajax.cfm

<!---Prevent any layouts from being applied--->
<cfset request.layout=false>
<!--- Minimise white space by resetting the output buffer and only returning the following cfoutput --->
<cfcontent type="text/html; charset=utf-8" reset="yes"><cfoutput>#rc.result#</cfoutput>

controller.cfc

function init( fw )
{
variables.fw=arguments.fw;
return this;
}

function getAjaxResponse( rc )
{
    rc.result=1;
    fw.setView( "main.ajax" );
}

function getAnotherAjaxResponse( rc )
{
    rc.result=0;
    fw.setView( "main.ajax" );
}

Answer 3

您可以在Application.cfc中使用onMissingView来处理ajax调用的响应，这样就不需要在控制器方法中执行任何额外的逻辑。

// Application.cfc 
function onMissingView(rc) {
  if(structKeyExists(rc, "ajaxdata") && isAjaxRequest()) {
    request.layout = false;
    content type="application/json";
    return serializeJSON(rc.ajaxdata);
  }
  else {
    return view("main/notfound");
  }
}

function isAjaxRequest() {
  var headers = getHttpRequestData().headers;
  return structKeyExists(headers, "X-Requested-With") 
         && (headers["X-Requested-With"] eq "XMLHttpRequest");
}

// controller cfc
function dosomething(rc) {
  rc.ajaxdata = getSomeService().doSomething(); 
}

这将检查请求上下文是否具有ajaxdata键，以及是否为真正的ajax请求，然后返回序列化数据。如果不是，则呈现main.notfound视图