如何使用envi设置头功能？

Question

我不明白envi_setup_head的意思。有人能帮我把它写成IDL代码格式吗？

我有用IDL生成的地图，我需要在ENVI中处理它们。我不知道如何将图片保存在文件夹中，并且可以在ENVI中打开它们。有人知道怎么做吗？

Answer 1

要为图像文件创建ENVI头文件，可以尝试下面的IDL过程。它创建了一个小图像文件，并使用envi_setup_head创建了一个ENVI头文件。基本上，您所要做的就是向它提供样本数量、行、数据类型等，您就可以开始工作了。

pro enviHeaderTest
    compile_opt idl2

    ; Create the data and write to a file.
    ns = 100
    nl = 100
    data = dist(ns, nl)
    fname = 'mydatafile.dat'
    openw, lun, fname, /GET_LUN
    writeu, lun, data
    close, lun

    ; Open a headless ENVI.
    nv = envi(/HEADLESS)

    ; Create some map info for the raster.
    mc = [0,0,0,0] ;Tie point: [x pixel, ypixel, x map, y map]
    ps = [1D/3600, 1D/3600] ; Pixel size
    mapInfo = envi_map_info_create(/GEOGRAPHIC, MC=mc, PS=ps)

    ; Create the header.
    envi_setup_head, FNAME=fname, $ ; file name
        NS=ns, $                    ; number of samples
        NL=nl, $                    ; number of lines
        NB=1, $                     ; number of bands
        DATA_TYPE=4, $              ; IDL data type (float in this case)
        INTERLEAVE=0, $             ; BSQ
        MAP_INFO=mapInfo, $
        /WRITE

    ; Close ENVI.
    nv.close
end

然后，您可以从File->Open菜单或通过IDL命令行将图像读取到ENVI中，如下所示：

IDL> nv = envi()
ENVI> view = nv.getview()
ENVI> raster = nv.openraster('mydatafile.dat')
ENVI> layer = view.createlayer(raster)