如何将配对列表添加到auto-mode- list？

Question

我有一个很长的文件和文件扩展名列表，我希望Emacs在ruby模式下自动打开它们。通过使用Google，最基本的解决方案是：

(setq auto-mode-alist (cons '("\.rake$"    . ruby-mode) auto-mode-alist))
(setq auto-mode-alist (cons '("\.thor$"    . ruby-mode) auto-mode-alist))
(setq auto-mode-alist (cons '("Gemfile$"   . ruby-mode) auto-mode-alist))
(setq auto-mode-alist (cons '("Rakefile$"  . ruby-mode) auto-mode-alist))
(setq auto-mode-alist (cons '("Crushfile$" . ruby-mode) auto-mode-alist))
(setq auto-mode-alist (cons '("Capfile$"   . ruby-mode) auto-mode-alist))

对我来说这似乎是重复的。有没有一种方法，我可以只定义一次配对列表，然后直接在auto-mode-alist上循环或反转它？我试过了

(cons '(("\\.rake" . ruby-mode)
         ("\\.thor" . ruby-mode)) auto-mode-alist)

但这似乎并不管用。有什么建议吗？

Answer 1

您只需要一个正则表达式(以及auto-mode-alist中的条目)来匹配所有这些选项，您可以让regexp-opt为您构建它。

(let* ((ruby-files '(".rake" ".thor" "Gemfile" "Rakefile" "Crushfile" "Capfile"))
       (ruby-regexp (concat (regexp-opt ruby-files t) "\\'")))
  (add-to-list 'auto-mode-alist (cons ruby-regexp 'ruby-mode)))

如果你特别想要单独的条目，你可以这样做：

(mapc
 (lambda (file)
   (add-to-list 'auto-mode-alist
                (cons (concat (regexp-quote file) "\\'") 'ruby-mode)))
 '(".rake" ".thor" "Gemfile" "Rakefile" "Crushfile" "Capfile"))

Answer 2

cons获取一个项目和一个列表，并返回一个新的列表，该列表的头部是该项目。(例如，(cons 1 '(2 3))给出了'(1 2 3))

您想要做的是获取一个列表和一个列表，并将它们append在一起

(setq auto-mode-alist
  (append '(("\\.rake" . ruby-mode)
            ("\\.thor" . ruby-mode))
   auto-mode-alist))

Answer 3

我最喜欢的是

(push '("\\(\\.\\(rake\\|thor\\)\\|\\(Gem\\|Rake\\|Crush\\|Cap\\)file\\)\\'" . ruby-mode) auto-mode-alist)