创建和释放TPopupMenu使用的TMenuItem

Question

创建TMenuItem运行时，如下所示：

mi := TMenuItem.Create([owner]);

并像这样添加到TPopupMenu中：

PopupMenu1.Items.Add(mi);

是否需要将[owner]指定为PopupMenu1，或者是否可以使用nil

在这种情况下，PopupMenu1会免费使用mi吗?如果是这样，我如何验证它？

Answer 1

您可以将nil指定为所有者，父项将释放其自己的项。

至于验证，最简单的方法是查看TMenuItem.Destroy中的代码：

destructor TMenuItem.Destroy;
begin
  ..
  while Count > 0 do Items[0].Free;  
  ..
end;

如果这还不够，可以使用通知机制来查看它的实际效果：

type
  TForm1 = class(TForm)
    PopupMenu1: TPopupMenu;
    Button1: TButton;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    mi: TMenuItem;
  protected
    procedure Notification(AComponent: TComponent; Operation: TOperation);
      override;
  end;

  ..

procedure TForm1.Button1Click(Sender: TObject);
begin
  mi := TMenuItem.Create(nil);
  mi.FreeNotification(Self);
  PopupMenu1.Items.Add(mi);
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  PopupMenu1.Free;
end;

procedure TForm1.Notification(AComponent: TComponent; Operation: TOperation);
begin
  inherited;
  if (AComponent = mi) and (Operation = opRemove) then
    ShowMessage('mi freed');
end;

按Button1键首先将项目添加到弹出菜单中。然后按Button2释放弹出窗口。当项目被销毁时，它将通知您的表单。