比较整数的整数数组VB.NET

Question

基本上我有一个大小不同的整数数组。我需要将每个数字相互比较，并显示哪个数字是重复的。例如：

Dim ints() As Integer = {1,2,2,5,4,6}

出现多次的数字是2。

如何遍历数组并将每个整数与数组中的数字进行比较。我尝试了一个for循环，但是它没有返回我想要的值。我是VB.NET的新手，不能完全理解。

Answer 1

Dim ints() As Integer = {1,2,2,5,4,6}

Dim repeatedNumbers = ints.GroupBy(Function(intValue) intValue) _
                          .Where(Function(grp) grp.Count > 1)

For each grp in repeatedNumbers
    Console.WriteLine("Number {0} is repeated {1} times", grp(0), grp.Count)
Next

这段代码的作用是：

• 我们首先调用GroupBy，它根据项的值对项进行分组。该函数获取分组键，在本例中，我们只需按数组本身的值进行分组。此调用返回一系列组。数组中的每个唯一值都有一个组。该组包含与唯一值相对应的所有项目。因此，如果一个值在数组中出现两次，就会有一个包含两个整数的组。
• 我们调用Where来筛选组。我们只需要计数大于1的组，这样就只考虑重复的值。
• 然后循环结果。grp(0)给出了组中的第一个数字(我们可以选择组中的任何数字，因为组中的所有数字都是相同的！)Count属性给出了重复次数。

Answer 2

我会用下面这样的方式来尝试：

    Dim ints() As Integer = {1, 2, 2, 5, 4, 6}
    Array.Sort(ints)
    For i = 1 To ints.GetUpperBound(0)
        If ints(i) = ints(i - 1) Then MessageBox.Show(String.Format("{0} is repeated", ints(i)))
    Next

在排序数组上这样做可以减少嵌套。

我没有对此进行测试，但它应该是正确的。

Answer 3

您可以使用LINQ查找重复项：

Dim repeating = (From n In ints
                 Group By n Into Dups = Group
                 Where Dups.Count > 1
                 Select Dups.First).ToArray()

这将返回一个整数数组，其中只包含在原始数组中不唯一的数字。

因此，这将显示重复的数字：

MessageBox.Show(String.Format("Duplicates found: {0}", String.Join(","c, repeating)))