如何批量压缩一个图像目录加上一个js和一个html文件，win7

Question

我想做一个批量压缩文件的操作。每个压缩文件的共同点是图像目录以及同名的*.js和*.html文件。

Answer 1

7zip有一个非常整洁的command line interface (它也是7zip文档的一部分；有关更多信息，请参阅http://7-zip.org )，可以在.bat文件中使用它来创建任何复杂的归档文件。

首先，尝试使用以下批处理文件(例如，另存为generate.bat)。它将遍历工作目录的所有子目录，并将子目录的所有文件添加到名为子目录的自己的.zip文件中。之后，相应的.js和.html文件将被添加到归档中。

@echo off

SET SEVENZIP=C:\Program Files\7-Zip\7z.exe
:: if 7z.exe is available within your PATH the following is sufficient: SET SEVENZIP=7z.exe

:: remember initial (current) directory
SET INITIAL_DIR=%CD%

:: define working directory
SET WORKING_DIR=%1
IF "%WORKING_DIR%" == "" (
   ECHO No input directory given using current directory...
   SET WORKING_DIR=%INITIAL_DIR%
)


:: change to working directory
CHDIR /D "%WORKING_DIR%"

:: loop over sub-directories
for /D %%a in (*) do (
    ECHO.
    ECHO.
    ECHO *** Creating %%a.zip ***

    :: add all files within images directory with name %%a
    "%SEVENZIP%" a "%%a.zip" "%%a\*"

    :: add .js and .html file
    "%SEVENZIP%" a "%%a.zip" "%%a.js"
    "%SEVENZIP%" a "%%a.zip" "%%a.html"
)

:: change back to original directory
CHDIR /D "%INITIAL_DIR%"


:end
ECHO.
ECHO.
PAUSE

要运行它，要么将其复制到您的工作目录中，要么使用Windows资源管理器，然后将工作目录拖放到.bat文件中。