谓词为true的集合中除最后一个元素外的所有元素的序列

Question

我在编写优雅的drop-last-by或butlast-by函数时遇到了麻烦。

(drop-last-by odd? [2 1 9 4 7 7 3])  ; => (2 1 9 4)
(drop-last-by odd? [2 4])  ; => (2 4)
(drop-last-by odd? [9])  ; => ()

到目前为止，我所做的一切都很好用，但看起来有点笨拙，我想知道是否可以只用两三行代码就能完成。

(defn drop-last-by [pred coll]
  (let [p (partition-by pred coll)]
    (apply concat (if (and (seq p) (pred (first (last p))))
                    (butlast p)
                    p))))

Answer 1

由于drop-while基本上已经完成了您所需的工作，并且您当前的解决方案已经不是懒惰的，因此我将drop-last-by编写为：

(defn drop-last-by [pred coll]
  (reverse (drop-while pred (reverse coll))))

Answer 2

下面的版本懒惰到了问题规范所允许的程度：

1. 不满足谓词的任何元素都会立即传递，而不会从源中读取任何其他元素；
2. 只要从源读入不满足谓词的元素，就会传递满足该谓词的任何元素；
3. 会删除满足该谓词且后面没有其他不满足该谓词的元素的任何元素。

此外，它还可以用作(有状态的)转换器；实际上，延迟序列版本是根据转换器和clojure.core/sequence实现的。

(defn drop-last-by
  ([pred]
   (fn [rf]
     (let [xs (volatile! [])]
       (fn
         ([] (rf))
         ([result] (rf result))
         ([result input]
          (if-not (pred input)
            (do
              (reduce rf result @xs)
              (vreset! xs [])
              (rf result input))
            (do
              (vswap! xs conj input)
              result)))))))
  ([pred coll]
   (sequence (drop-last-by pred) coll)))

在REPL：

(drop-last-by odd? [2 1 9 4 7 7 3])
;= (2 1 9 4)
(drop-last-by odd? [2 4])
;= (2 4)
(drop-last-by odd? [9])
;= ()

与其他传感器组成：

(into []
      (comp (drop-while even?)
            (drop-last-by odd?)
            (map #(str "foo " %)))
      [0 1 2 3 4 5])
;= ["foo 1" "foo 2" "foo 3" "foo 4"]