使用Manipulate的mathematica图不显示任何输出

Question

我最初尝试使用Plot3D和操纵滑块来可视化一个4参数函数(其中两个参数由滑块控制，另一个参数在"x-y“平面上变化)。但是，当我的非绘图参数被操纵控制时，我得不到任何输出？

下面的1d绘图示例复制了我在更复杂的绘图尝试中看到的内容：

Clear[g, mu]
g[ x_] = (x Sin[mu])^2 
Manipulate[ Plot[ g[x], {x, -10, 10}], {{mu, 1}, 0, 2 \[Pi]}] 
Plot[ g[x] /. mu -> 1, {x, -10, 10}] 

具有固定值µ的绘图在{0,70}自动选择的绘图范围内具有预期的抛物线输出，而操纵绘图在{0，1}范围内为空。

我怀疑在使用mu滑块控件时，PlotRange的默认设置不是很好，但手动添加PlotRange也没有显示任何输出：

Manipulate[ Plot[ g[x], {x, -10, 10}, PlotRange -> {0, 70}], {{mu, 1}, 0, 2 \[Pi]}]

Answer 1

这是因为Manipulate参数是本地的。

Manipulate[ Plot[ g[x], {x, -10, 10}], {{mu, 1}, 0, 2 \[Pi]}]中的mu与您在上一行中清除的全局mu不同。

我建议使用

g[x_, mu_] := (x Sin[mu])^2
Manipulate[Plot[g[x, mu], {x, -10, 10}], {{mu, 1}, 0, 2 \[Pi]}]

下面的方法也有效，但它会不断更改全局变量的值，除非您注意，否则可能会在以后引起意外，所以我不推荐使用它：

g[x_] := (x Sin[mu])^2
Manipulate[
 mu = mu2;
 Plot[g[x], {x, -10, 10}],
 {{mu2, 1}, 0, 2 \[Pi]}
]

可能会发生这样的情况，当Clear[mu]对象滚动到视图中时，它会获得一个值。

Answer 2

克服Manipulate本地化的另一种方法是将函数放在Manipulate[]中

Manipulate[Module[{x,g},
  g[x_]=(x Sin[mu])^2;
  Plot[g[x], {x, -10, 10}]], {{mu, 1}, 0, 2 \[Pi]}]

甚至是

Manipulate[Module[{x,g},
  g=(x Sin[mu])^2;
  Plot[g, {x, -10, 10}]], {{mu, 1}, 0, 2 \[Pi]}]

两者都给出了

​

​

Module[{x,g},...]可防止来自全局上下文的不必要的副作用。这就实现了g的简单定义:我已经有了具有数十个可调参数的Manipulate[]ed图，当将所有这些参数作为参数传递给函数时，这些参数可能会很麻烦。