首页
学习
活动
专区
圈层
工具
发布
社区首页 >问答首页 >当你把光标放在Vim fold上时,有没有办法自动展开它?

问当你把光标放在Vim fold上时,有没有办法自动展开它?
EN

Stack Overflow用户
提问于 2011-08-12 07:45:58
回答 3查看 2K关注 0票数 9

你能让Vim在光标接触时自动展开折叠吗?

EN

回答 3

Stack Overflow用户

回答已采纳

发布于 2011-08-12 13:31:39

请参见foldopen选项。它控制当光标移动到闭合的折叠中时,哪些命令组将导致打开折叠。

但请注意,垂直移动不会打开闭合的折叠。此外,foldopen中没有启用此行为的设置。当在foldopen选项中设置了hor项目时,可以使用h、l或其他水平移动命令打开折叠。如果在任何光标移动上自动打开折叠是至关重要的,则可以通过重新映射垂直移动命令的某个子集来解决此问题,如下所示。

代码语言:javascript
复制
nnoremap <silent> j :<c-u>call MoveUpDown('j', +1, 1)<cr>
nnoremap <silent> k :<c-u>call MoveUpDown('k', -1, 1)<cr>
nnoremap <silent> gj :<c-u>call MoveUpDown('gj', +1, 1)<cr>
nnoremap <silent> gk :<c-u>call MoveUpDown('gk', -1, 1)<cr>
nnoremap <silent> <c-d> :<c-u>call MoveUpDown("\<lt>c-d>", +1, '&l:scroll')<cr>
nnoremap <silent> <c-u> :<c-u>call MoveUpDown("\<lt>c-u>", -1, '&l:scroll')<cr>
nnoremap <silent> <c-f> :<c-u>call MoveUpDown("\<lt>c-f>", +1, 'winheight("%")')<cr>
nnoremap <silent> <c-b> :<c-u>call MoveUpDown("\<lt>c-b>", -1, 'winheight("%")')<cr>
function! MoveUpDown(cmd, dir, ndef)
    let n = v:count == 0 ? eval(a:ndef) : v:count
    let l = line('.') + a:dir * n
    silent! execute l . 'foldopen!'
    execute 'norm! ' . n . a:cmd
endfunction

一个不太好,但更节俭的解决方案是在每次光标移动时打开一个折叠。

代码语言:javascript
复制
autocmd CursorMoved,CursorMovedI * silent! foldopen

不幸的是,这个解决方案不是通用的。打开光标下的文件夹后,光标将定位在该文件夹的第一行。如果此行为不受欢迎,可以沿着移动的垂直方向移动,并在光标自下而上移动时将光标放在折叠的最后一行上。

代码语言:javascript
复制
autocmd CursorMoved,CursorMovedI * call OnCursorMove()
function! OnCursorMove()
    let l = line('.')
    silent! foldopen
    if exists('b:last_line') && l < b:last_line
        norm! ]z
    endif
    let b:last_line = l
endfunction

但是,如果移动跳过折叠,则不会打开该折叠。例如,位于折叠上方的行上的2j会将光标放在紧跟在该折叠之后的行上,而不是其中的第二行。

票数 5
EN

Stack Overflow用户

发布于 2011-08-12 16:54:27

代码语言:javascript
复制
set foldopen=all

看起来你想做什么就做什么。您还可以设置光标移动的自动命令:

代码语言:javascript
复制
au CursorMoved * call AutoOpen()

调用如下函数:

代码语言:javascript
复制
function! AutoOpen()
  if foldclosed(".") == line(".")
    call feedkeys("zo")
  endif
endfunction

如果您希望此功能也在插入模式下工作,请使用:

代码语言:javascript
复制
au CursorMoved,CursorMovedI * call AutoOpen()
票数 3
EN

Stack Overflow用户

发布于 2011-08-12 13:31:46

:help fdo和:help fcl可能会对您有所帮助。我的.vimrc中有这样一行代码:

代码语言:javascript
复制
set foldopen=block,hor,insert,jump,mark,percent,quickfix,search,tag,undo
票数 1
EN
页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持
原文链接:

https://stackoverflow.com/questions/7034215

复制
相关文章

相似问题

领券
问题归档专栏文章快讯文章归档关键词归档开发者手册归档开发者手册 Section 归档