FParsec中的递归语法

Question

我决定检查FParsec，并尝试为λ表达式编写一个解析器。事实证明，迫不及待使得递归解析变得困难。我该如何解决这个问题呢？

代码：

open FParsec

type λExpr =
    | Variable of char
    | Application of λExpr * λExpr
    | Lambda of char * λExpr

let rec FV = function
    | Variable v -> Set.singleton v
    | Application (f, x) -> FV f + FV x
    | Lambda (x, m) -> FV m - Set.singleton x

let Λ0 = FV >> (=) Set.empty

let apply f p =
    parse
        { let! v = p
          return f v }

let λ e =

    let expr, exprR = createParserForwardedToRef()

    let var = lower |> apply Variable

    let app = tuple2 expr expr
                 |> apply Application

    let lam = pipe2 (pchar 'λ' >>. many lower)
                        (pchar '.' >>. expr) (fun vs e ->
                                                List.foldBack (fun c e -> Lambda (c, e)) vs e)

    exprR := choice [
                    lam
                    app
                    var
                    (pchar '(' >>. expr .>> pchar ')')
                    ]

    run expr e

谢谢!

Answer 1

正如您所指出的，问题是您的应用程序解析器递归地调用expr，因此会有一个无限循环。需要编写解析器，使其始终使用一些输入，然后决定要做什么。

在λ微积分的情况下，棘手的事情是识别一个应用程序和一个变量，因为如果你有像x...这样的输入，那么第一个字符表明它可能是它们中的任何一个。

您可以合并应用程序和变量的规则，如下所示：

let rec varApp = parse {
  let! first = lower |> apply Variable
  let! res = 
    choice [ expr |> apply (fun e -> Application(first, e))
             parse { return first } ]
  return res }

它首先解析一个变量，然后解析另一个表达式(在这种情况下，它是一个应用程序)，或者只返回变量(如果变量后面没有表达式)。其余的规则是相似的：

and lam = 
  pipe2 (pchar 'λ' >>. many lower)
        (pchar '.' >>. expr) (fun vs e ->
    List.foldBack (fun c e -> Lambda (c, e)) vs e)
and brac = pchar '(' >>. expr .>> pchar ')'
and expr = parse.Delay(fun () ->
  choice 
    [ lam; varApp; brac ])

我只是通过使用parse.Delay()避免了显式突变的需要(这使得创建递归值引用成为可能)。原则上，它可以写成：

and expr = parse {
  return! choice [ lam; varApp; brac ] }

...but由于某种原因，如果您想在计算表达式中使用ReturnFrom，则FParsec不会实现所需的return!成员。