从图(而不是Hermite)中识别Mathematica插值函数

Question

我正在对Mathematica做列表插值的方式进行逆向工程：

(* Fortunately, Mathematica WILL interpolate an arbitrary list *) 

tab = Table[a[i], {i,1,100}] 

f = Interpolation[tab] 

(* get the coefficient of each term by setting others to zero *) 

Plot[{f[42+x] /. {a[42] -> 0, a[43] ->0, a[44] -> 0, a[41] -> 1}}, 
 {x,0,1}] 

Plot[{f[42+x] /. {a[41] -> 0, a[43] ->0, a[44] -> 0, a[42] -> 1}}, 
 {x,0,1}] 

Plot[{f[42+x] /. {a[42] -> 0, a[41] ->0, a[44] -> 0, a[43] -> 1}}, 
 {x,0,1}] 

Plot[{f[42+x] /. {a[42] -> 0, a[43] ->0, a[41] -> 0, a[44] -> 1}}, 
 {x,0,1}] 

(* above is neither Hermite, nor linear, though some look close *) 

(* these are available at oneoff.barrycarter.info/STACK/ *) 

Table[f[42+x] /. {a[42] -> 0, a[43] ->0, a[44] -> 0, a[41] -> 1}, 
 {x,0,1, 1/100}] >> /home/barrycarter/BCINFO/ONEOFF/STACK/coeff41.txt 

Table[f[42+x] /. {a[41] -> 0, a[43] ->0, a[44] -> 0, a[42] -> 1}, 
 {x,0,1, 1/100}] >> /home/barrycarter/BCINFO/ONEOFF/STACK/coeff42.txt 

Table[f[42+x] /. {a[41] -> 0, a[42] ->0, a[44] -> 0, a[43] -> 1}, 
 {x,0,1, 1/100}] >> /home/barrycarter/BCINFO/ONEOFF/STACK/coeff43.txt 

Table[f[42+x] /. {a[41] -> 0, a[42] ->0, a[43] -> 0, a[44] -> 1}, 
 {x,0,1, 1/100}] >> /home/barrycarter/BCINFO/ONEOFF/STACK/coeff44.txt

编辑:谢谢，whuber！这正是我想要的。作为参考，系数为(按顺序)：

(x-2)*(x-1)*x/-6
(x-2)*(x-1)*(x+1)/2
x*(x+1)*(x-2)/-2
(x-1)*x*(x+1)/6

Answer 1

根据文献，插值器是分段多项式的。这有点含糊，所以这里有一些需要调查的东西。

您可以通过实验确定内插器是数据的线性函数。所有可能数据的良好基础由以下形式的向量组成：{1,0，...,0}，{0,1,0，...,0}，...，{0，...,0,1}。为此，让我们构建一个小函数来生成这些长度为$n$的向量：

test[n_, i_] := Module[{x = ConstantArray[0,n]},x[[i]] = 1; x]

您可以通过尝试像这样的一些示例来确认线性，其中系数$a$和$b$作用于长度为$n$的$i^\text{th}$和$j^\text{th}$基向量：

With[{a=1, b=2.5, n=5, i=2, j=3},
    Plot[{Interpolation[a test[n,i] + b test[n,j]][x], 
        a Interpolation[test[n,i]][x] + b Interpolation[test[n,j]][x]}, {x, 1, n}]
]

将只有一条曲线，因为这两个函数是叠加的。

在建立了线性关系之后，只需在$n$基向量上分析内插器的值就足够了。你可以通过微分来确定多项式的次数。默认情况下，度数为3，但您可以使用"InterpolatingOrder“参数修改度数。下面的代码将使用长度为$n$的数据的所有基向量绘制一个明显分段的常数曲线表，该曲线表由插值器的导数产生，用于插值阶数1到ioMax：

With[{n=7, ioMax = 5},
    Table[
        Module[{fns},
            fns = Table[Interpolation[test[n,i], InterpolationOrder->io], {i,1,n}];
            Table[Plot[Evaluate@D[f[#], {#,io}]&[x], {x,1,n},
                PlotRange->Full, PlotStyle->Thick, ImageSize->150], {f, fns}]
        ], {io, 1, ioMax}
    ]
] // TableForm

输出显示，中断发生在参数的整数值处，并且对于长度为$n$的数据和次数为$d$的插值器，最多有$n-d$ distinct段。这些信息应该会让你大体上做到这一点。