线程安全在clojure中流行吗？

Question

我在http://www.learningclojure.com/2010/11/yet-another-way-to-write-factorial.html上找到了这段代码，但我不明白弹出任务是否应该是线程安全的，或者是如何实现的。难道不允许返回两次相同的头吗？

(def to-do-list (atom '()))  
(defn add-task![t] (swap! to-do-list #(cons t %)))  
(defn pop-task![] (let [h (first @to-do-list)] (swap! to-do-list rest) h))

如果是这样的话，有没有可能继续使用atom并编写peek和交换！原子操作，或者这是ref机制的工作？

Answer 1

或者你降到一个更低的级别。

(def to-do-list (atom nil))

(defn add-task!
   [t]
   (swap! to-do-list conj t))

(defn pop-task!
   []
   (let [[h & r :as l] @to-do-list]
     (if (compare-and-set! to-do-list l r)
       h
       (recur))))

Answer 2

是的，这段代码不是线程安全的。你可以让它成为线程安全的，通过利用交换！返回原子的新值，这意味着您需要将队列与"popped“值组合在一起。

(def to-do-list
  (atom {}))

(defn add-task!
  [t]
  (swap! to-do-list
         (fn [tl]
           {:queue (cons t (:queue tl))})))

(defn pop-task!
  []
  (let [tl (swap! to-do-list
                  (fn [old]
                    {:val (first (:queue old))
                     :queue (rest (:queue old))}))]
    (:val tl)))