FastMM:分配的总内存

Question

如何获取FastMM分配的内存总量？

我试过了：

function GetTotalAllocatedMemory: Cardinal;
var
  MMState: TMemoryManagerState;
begin
  GetMemoryManagerState(MMState);
  Result := MMState.TotalAllocatedMediumBlockSize + MMState.TotalAllocatedLargeBlockSize;
end;

这是正确的吗？

无论如何，它返回一些奇怪的东西。它比我在Windows任务管理器中看到的值小5倍。我相信Delphi应用程序分配的内存量等于FastMM分配的内存加上一些系统开销。我说错了吗？

Answer 1

使用以下命令：

//------------------------------------------------------------------------------  
// CsiGetApplicationMemory  
//  
// Returns the amount of memory used by the application (does not include  
// reserved memory)  
//------------------------------------------------------------------------------  
function CsiGetApplicationMemory: Int64;  
var  
  lMemoryState: TMemoryManagerState;  
  lIndex: Integer;  
begin  
  Result := 0;  

  // get the state  
  GetMemoryManagerState(lMemoryState);  

  with lMemoryState do begin  
    // small blocks  
    for lIndex := Low(SmallBlockTypeStates) to High(SmallBlockTypeStates) do  
      Inc(Result,  
          SmallBlockTypeStates[lIndex].AllocatedBlockCount *  
          SmallBlockTypeStates[lIndex].UseableBlockSize);  

    // medium blocks  
    Inc(Result, TotalAllocatedMediumBlockSize);  

    // large blocks  
    Inc(Result, TotalAllocatedLargeBlockSize);  
  end;  
end;

Answer 2

你在拿苹果和桔子作比较。

FastMM内存是指通过FastMM分配的内存使用情况。

这至少不包括以下内容：

• FastMM FastMM代表您分配的块的开销
• FastMM未分配的内容的开销(如您的进程空间中的DLL占用的空间)

图形用户界面应用程序的

• ：GDI、GDI+、DirectX、OpenGL和其他为您分配的可视对象的存储的开销。

--jeroen

Answer 3

对于进程内存，请使用以下命令：

//------------------------------------------------------------------------------
// CsiGetProcessMemory
//
// Return the amount of memory used by the process
//------------------------------------------------------------------------------
function CsiGetProcessMemory: Int64;
var
  lMemoryCounters: TProcessMemoryCounters;
  lSize: Integer;
begin
  lSize := SizeOf(lMemoryCounters);
  FillChar(lMemoryCounters, lSize, 0);
  if GetProcessMemoryInfo(CsiGetProcessHandle, @lMemoryCounters, lSize) then
    Result := lMemoryCounters.PageFileUsage
  else
    Result := 0;
end;