如何在Inno-setup中更改文件关联

Question

我需要用户能够双击一个.pdb文件，并用myPgm.exe打开它。

将文件类型(myData.pdb)与可执行文件(myPgm.exe)关联的语法是什么？

它是注册表项吗？

Answer 1

文件关联是一系列注册表项。有关更多信息，请查看How to Use File Associations Microsoft Sample。

如果你不想创建系统范围的文件关联，你也可以创建specific user file associations。

要从脚本创建注册表项，请阅读ISS Documentation: Registry Section。如果你发现任何问题，带着一个更具体的问题回来。

Answer 2

Inno Setup网站上有an entry for that in the FAQ。以下是常见问题相关部分的引述：

创建文件关联

首先将[Setup]段指令ChangesAssociations设置为yes。然后创建[Registry]条目，如下所示。

[Registry]
Root: HKCR; Subkey: ".myp"; ValueType: string; ValueName: ""; ValueData: "MyProgramFile"; Flags: uninsdeletevalue

".myp"是我们要关联的扩展名。"MyProgramFile"是存储在注册表中的文件类型的内部名称。确保使用唯一的名称，这样就不会无意中覆盖另一个应用程序的注册表项。

Root: HKCR; Subkey: "MyProgramFile"; ValueType: string; ValueName: ""; ValueData: "My Program File"; Flags: uninsdeletekey

上面的"My Program File"是资源管理器中显示的文件类型的名称。

Root: HKCR; Subkey: "MyProgramFile\DefaultIcon"; ValueType: string; ValueName: ""; ValueData: "{app}\MYPROG.EXE,0"

"DefaultIcon"是指定包含要与文件类型关联的图标的文件名的注册表项。",0"告诉资源管理器使用MYPROG.EXE中的第一个图标。(",1"指的是第二个图标。)

Root: HKCR; Subkey: "MyProgramFile\shell\open\command"; ValueType: string; ValueName: ""; ValueData: """{app}\MYPROG.EXE"" ""%1"""

"shell\open\command"是一个注册表项，它指定在资源管理器中双击该类型的文件时要执行的程序。两边的引号在命令行中，因此它可以正确地处理长文件名。

Answer 3

这对我来说很好。只需重命名MYEXTENSION

[Registry]
Root: HKA ; Subkey: "Software\Classes\.MYEXTENSION"; ValueData: "{#MyAppName}"; Flags: uninsdeletevalue; ValueType: string; ValueName: ""
Root: HKA ; Subkey: "Software\Classes\{#MyAppName}"; ValueData: "{app}\{#MyAppExeName}";  Flags: uninsdeletekey; ValueType: string; ValueName: ""
Root: HKA ; Subkey: "Software\Classes\{#MyAppName}\DefaultIcon"; ValueData: "{app}\{#MyAppExeName},0"; ValueType: string;  ValueName:""
Root: HKA ; Subkey: "Software\Classes\{#MyAppName}\shell\open\command"; ValueData: """{app}\{#MyAppExeName}"" ""%1""";  ValueType: string; ValueName: ""