Emacs Lisp - mapcar没有将函数应用到所有元素吗？

Question

我有一个函数，它接受一个列表并替换一些元素。我将它构造为一个闭包，这样就不能在函数外部修改自由变量。

(defun transform (elems)
  (lexical-let ( (elems elems) )
    (lambda (seq)
      (let (e)
    (while (setq e (car elems))
      (setf (nth e seq) e)
      (setq elems (cdr elems)))
    seq))))

我在一个列表列表上调用它。

(defun tester (seq-list)
  (let ( (elems '(1 3 5)) )
    (mapcar (transform elems) seq-list)))

(tester (list (reverse (number-sequence 1 10)) 
          '("a" "b" "c" "d" "e" "f")))
=> ((10 1 8 3 6 5 4 3 2 1) ("a" "b" "c" "d" "e" "f"))

它似乎没有将该函数应用于提供给tester()的列表的第二个元素。但是，如果我显式地将此函数应用于各个元素，它将工作...

(defun tester (seq-list)
  (let ( (elems '(1 3 5)) )
    (list (funcall (transform elems) (car seq-list))
          (funcall (transform elems) (cadr seq-list)))))

(tester (list (reverse (number-sequence 1 10)) 
          '("a" "b" "c" "d" "e" "f")))
=> ((10 1 8 3 6 5 4 3 2 1) ("a" 1 "c" 3 "e" 5))

如果我使用与上面相同的概念编写一个简单的函数，mapcar似乎可以工作……我能做错什么呢？

(defun transform (x)
  (lexical-let ( (x x) )
    (lambda (y) 
      (+ x y))))

(defun tester (seq)
  (let ( (x 1) )
    (mapcar (transform x) seq)))

(tester (list 1 3))    
=> (2 4)

谢谢

Answer 1

在第一次调用闭包之后，闭合变量elems被设置为nil；因此所有后续调用都只能看到nil。您的第二个示例之所以有效，是因为每个transform实例都会生成一个新的闭包。

这应该是可行的：

(defun transform (elems)
  (lexical-let ((elems elems))
    (lambda (seq)
      (dolist (e elems seq)
        (setf (nth e seq) e)))))