从CMake脚本构建doxygen

Question

我在网上找到了一个示例cmake文件，并将其放在我的项目的DOOX子目录中，myproject.doxgen文件也位于这个子目录中，其中包含/doc配置。

我已经测试过，运行doxygen.exe myproject.doxygen会产生有效的输出。我只需要将它构建到CMake过程中。所以/doc/CMakeLists.txt是：

find_package(Doxygen)
option(BUILD_DOCUMENTATION "Create and install the HTML based API        
documentation (requires Doxygen)" ${DOXYGEN_FOUND})

if(BUILD_DOCUMENTATION)
    if(NOT DOXYGEN_FOUND)
         message(FATAL_ERROR "Doxygen is needed to build the documentation.")
    endif()

    set(doxyfile_in ${CMAKE_CURRENT_SOURCE_DIR}/../doc/myproject.doxygen)
    set(doxyfile ${CMAKE_CURRENT_BINARY_DIR}/doxyfile)

    configure_file(${doxyfile_in} ${doxyfile} @ONLY)

    message("Doxygen build started.")

    add_custom_target(doc
                      COMMAND ${DOXYGEN_EXECUTABLE} ${doxyfile_in}
                      WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/doc
                      COMMENT "Generating API documentation with Doxygen"
                      VERBATIM)

    #    install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/html DESTINATION     share/doc)
endif()

它对我不起作用，它只将原始的配置文件复制到/build/my/project/doc/中，其他什么也不做。

我想要的是在构建期间生成doxygen文档；理想情况下，仅在构建发布配置时生成。

Answer 1

按照您所展示的CMake文件的设置方式，它将创建一个名为doc的目标；构建该目标(例如运行make doc)将生成doxymentation。目标不是make all (或等效物)的一部分；要使其成为一部分，请将ALL添加到自定义目标创建中：

add_custom_target(
  doc ALL
  COMMAND #... everything else as before
)

如果您希望将此目标限制为仅在特定配置中构建(正如您在注释中提到的)，则可以使用generator expressions

add_custom_target(
  doc ALL
  COMMAND $<$<CONFIG:Release>:${DOXYGEN_EXECUTABLE} ${doxyfile_in}>
  WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/doc
  COMMENT "Generating API documentation with Doxygen"
  VERBATIM
)

有些CMake生成器可能不能很好地处理空COMMAND。考虑到这一点，以下内容应该是故障保护的：

add_custom_target(
  doc ALL
  COMMAND
    $<$<CONFIG:Release>:${DOXYGEN_EXECUTABLE} ${doxyfile_in}>
    $<$<NOT:$<CONFIG:Release>>:${CMAKE_COMMAND} -E echo "Only done in Release builds">
  WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/doc
  COMMENT "Generating API documentation with Doxygen"
  VERBATIM
)