获取Oracle表中所有列的max(length(column))

Question

我需要获取一组表中每列的最大数据长度。我可以单独处理每个表，但我正在寻找一种至少遍历表中所有列的方法。

我目前使用下面的查询来获取每列的最大值-

select max(length(exampleColumnName)) 
from exampleSchema.exampleTableName;

我基本上是用表中的每一列替换exampleColumnName。我已经经历了3-4个线程，但没有一个线程适合我，要么是因为它们不是为Oracle编写的，要么是因为它们有我需要的更多细节(我不能选择我需要的部分)。

我更喜欢在SQL中使用它，而不是PLSQL中，因为我没有任何create特权，也不能创建任何PLSQL对象。

Answer 1

让下面的查询起作用-

DECLARE
  max_length INTEGER; --Declare a variable to store max length in.
  v_owner VARCHAR2(255) :='exampleSchema';     -- Type the owner of the tables you are looking at

BEGIN
  -- loop through column names in all_tab_columns for a given table
  FOR t IN (SELECT table_name, column_name FROM all_tab_cols where owner=v_owner and table_name = 'exampleTableName') LOOP

    EXECUTE IMMEDIATE 
    -- store maximum length of each looped column in max_length variable
    'select nvl(max(length('||t.column_name||')),0) FROM '||t.table_name
    INTO max_length;

    IF max_length >= 0 THEN -- this isn't really necessary but just to ignore empty columns. nvl might work as well
      dbms_output.put_line( t.table_name ||' '||t.column_name||' '||max_length ); --print the tableName, columnName and max length
    END IF;

  END LOOP;
END;

一定要让我知道评论是否充分解释了这一点，否则我会努力做得更好。删除table_name = 'exampleTableName'可能也会对所有表进行循环，但现在这对我来说是可以的。

Answer 2

您可以尝试这样做；尽管它使用PL/SQL，但它可以在SQL-Plus中工作。它不会循环。希望您的列不会太多，以至于SELECT查询无法容纳32,767个字符！

SET SERVEROUTPUT ON
DECLARE
    v_sql VARCHAR2(32767);
    v_result NUMBER;
BEGIN
    SELECT 'SELECT GREATEST(' || column_list || ') FROM ' || table_name
      INTO v_sql
      FROM (
        SELECT table_name, LISTAGG('MAX(LENGTH(' || column_name || '))', ',') WITHIN GROUP (ORDER BY NULL) AS column_list
          FROM all_tab_columns
         WHERE owner = 'EXAMPLE_SCHEMA'
           AND table_name = 'EXAMPLE_TABLE'
         GROUP BY table_name
    );
    EXECUTE IMMEDIATE v_sql INTO v_result;
    DBMS_OUTPUT.PUT_LINE(v_result);
END;
/