Delphi TListBox OnClick / OnChange？

Question

用TListBox实现"OnChange“类型的功能有什么窍门吗？我可以子类化的组件，并添加一个属性，等等，然后只执行OnClick代码，如果索引改变…我也可以使用一个表单级别的变量来存储当前的索引，但是我只是想知道在我走这条路或那条路之前，我是否忽略了显而易见的事情。

Answer 1

似乎除了自己实现这一点之外，没有其他方法。您需要做的是记住当前选定的项目，并且每当ItemIndex属性从代码中更改时，或者每当控件接收到LBN_SELCHANGE通知(当前触发OnClick事件)时，您将比较您存储的项目索引和当前选定的项目索引，如果它们不同，则触发您自己的OnChange事件。在插入类的代码中，它可以是：

type
  TListBox = class(StdCtrls.TListBox)
  private
    FItemIndex: Integer;
    FOnChange: TNotifyEvent;
    procedure CNCommand(var AMessage: TWMCommand); message CN_COMMAND;
  protected
    procedure Change; virtual;
    procedure SetItemIndex(const Value: Integer); override;
  published
    property OnChange: TNotifyEvent read FOnChange write FOnChange;
  end;

implementation

{ TListBox }

procedure TListBox.Change;
begin
  if Assigned(FOnChange) then
    FOnChange(Self);
end;

procedure TListBox.CNCommand(var AMessage: TWMCommand);
begin
  inherited;
  if (AMessage.NotifyCode = LBN_SELCHANGE) and (FItemIndex <> ItemIndex) then
  begin
    FItemIndex := ItemIndex;
    Change;
  end;
end;

procedure TListBox.SetItemIndex(const Value: Integer);
begin
  inherited;
  if FItemIndex <> ItemIndex then
  begin
    FItemIndex := ItemIndex;
    Change;
  end;
end;

Answer 2

使用OnClick事件就像this...you需要存储最后一个值来比较它一样。

if ListBox1.Items[ListBox1.ItemIndex]<> Edit1.Text then
    Edit1.Text := ListBox1.Items[ListBox1.ItemIndex];