Clojure:正确的condp用法

Question

我正在用clojure重写我的世界历史网站(history.clmitchell.net)，并取得了很大的进展。我已经达到了需要使用条件来输出用于声明基于加载的页面的CSS链接的打卡代码的地步。我仔细阅读了文档，但无法弄清楚：

(defn cssfiles
  "load sets of CSS files depending on which page is being served"
  [pageName]
  (condp = pageName
         "index" (hic/include-css "/css/hcspry.css"
                                  "/css/menus.css"
                                  "/css/filter.css"
                                  "/css/wc3xhtml1.css")
         "add" (hic/include-css "/css/hcspry.css"
                                "/css/menus.css"
                                "/css/addform.css")
         "map" (hic/include-css "/css/hcspry.css"
                                "/css/menus.css"
                                "/css/SpryCollapsiblePanel.css"
                                "/css/SpryAccordion.css")
         "chart" (hic/include-css "/css/hcspry.css"
                                  "/css/menus.css"
                                  "/css/filter.css"
                                  "/css/cha.css")
         "learn" (hic/include-css "/css/hcspry.css"
                                  "/css/menus.css"
                                  "/css/filter.css"
                                  "/css/wc3xhtml1.css"
                                  "/css/doc.css")
         "changes" (hic/include-css "/css/hcspry.css"
                                    "/css/menus.css"
                                    "/css/filter.css"
                                    "/css/wc3xhtml1.css"
                                    "/css/clg.css")
         "seek" (hic/include-css "/css/hcspry.css"
                                 "/css/menus.css"))
  (println (str  "PRGMR. MSG: net.clm.history.pages.snippets.clj::(defn cssfiles [" pageName "]): unknown parameter or parameter not processed properly.")))

问:这种函数的正确语法是什么？

Answer 1

您可以将页面-css映射定义为单独的纯数据结构，并避免对hic/include-css的重复调用：

(def page-css-mapping
  {"index"   ["/css/hcspry.css"
              "/css/menus.css"
              "/css/filter.css"
              "/css/wc3xhtml1.css"]
   "add"     ["/css/hcspry.css"
              "/css/menus.css"
              "/css/addform.css"]
   "map"     ["/css/hcspry.css"
              "/css/menus.css"
              "/css/SpryCollapsiblePanel.css"
              "/css/SpryAccordion.css"]
   "chart"   ["/css/hcspry.css"
              "/css/menus.css"
              "/css/filter.css"
              "/css/cha.css"]
   "learn"   ["/css/hcspry.css"
              "/css/menus.css"
              "/css/filter.css"
              "/css/wc3xhtml1.css"
              "/css/doc.css"]
   "changes" ["/css/hcspry.css"
              "/css/menus.css"
              "/css/filter.css"
              "/css/wc3xhtml1.css"
              "/css/clg.css"]
   "seek"    ["/css/hcspry.css"
              "/css/menus.css"]})

(defn cssfiles
  "load sets of CSS files depending on which page is being served"
  [pageName]
  (if-let [css-files (get page-css-mapping pageName)]
    (apply hic/include-css css-files)
    (println (str "PRGMR. MSG: net.clm.history.pages.snippets.clj::(defn cssfiles [" pageName "]): unknown parameter or parameter not processed properly."))))

现在，您还可以将映射存储为普通数据结构(例如，作为EDN文件或数据)，而不是将其硬编码。

Answer 2

你是说你不确定函数cssfiles在做什么吗？在这种情况下，该函数表示：

如果我的参数pagename等于字符串"index"，那么执行可以在hic缩写的名称空间中找到的函数include-css，将参数"/css/hcspry.css"，"/css/menus.css"，...传递给该函数，并返回结果值作为我的(即cssfiles')返回值。

如果pagename等于"add"，则使用一组不同的参数执行include-css ...，返回结果值...(等)

对于作为pagename的可预测值的其他字符串，依此类推。

但是，如果pagename与我测试的任何字符串都不匹配，那么就执行condp表达式末尾的println语句，以便打印出一条错误消息。

有关语法的更多信息，请参阅condp的文档。不过，如果需要的话，我很乐意提供更多细节。

Answer 3

dskrvk是对的: println表单不在condp表单中；下面是更正后的函数：

(defn cssfiles
  "load sets of CSS files depending on which page is being served"
  [pageName]
  (condp = pageName
         "index" (hic/include-css "/css/hcspry.css"
                                  "/css/menus.css"
                                  "/css/filter.css"
                                  "/css/wc3xhtml1.css")
         "add" (hic/include-css "/css/hcspry.css"
                                "/css/menus.css"
                                "/css/addform.css")
         "map" (hic/include-css "/css/hcspry.css"
                                "/css/menus.css"
                                "/css/SpryCollapsiblePanel.css"
                                "/css/SpryAccordion.css")
         "chart" (hic/include-css "/css/hcspry.css"
                                  "/css/menus.css"
                                  "/css/filter.css"
                                  "/css/cha.css")
         "learn" (hic/include-css "/css/hcspry.css"
                                  "/css/menus.css"
                                  "/css/filter.css"
                                  "/css/wc3xhtml1.css"
                                  "/css/doc.css")
         "changes" (hic/include-css "/css/hcspry.css"
                                    "/css/menus.css"
                                    "/css/filter.css"
                                    "/css/wc3xhtml1.css"
                                    "/css/clg.css")
         "seek" (hic/include-css "/css/hcspry.css"
                                 "/css/menus.css")
         (println (str  "PRGMR. MSG: net.clm.history.pages.snippets.clj::(defn cssfiles [" pageName "]): unknown parameter or parameter not processed properly."))))