首页
学习
活动
专区
圈层
工具
发布
社区首页 >问答首页 >在处理中提取像素数据

问在处理中提取像素数据
EN

Stack Overflow用户
提问于 2015-08-07 06:47:02
回答 2查看 281关注 0票数 0

使用processing中的捕获视频,我想了解如何设置摄像机将不断扫描的一小部分摄像机提要。在定义的区域内,我想让相机寻找亮度的变化(即亮度现在变暗了)。如果亮度发生变化,我只想让它返回“检测到阴影”。有人能帮我入门吗?我对这门语言非常陌生。

EN

回答 2

Stack Overflow用户

发布于 2015-08-07 21:38:53

您可以使用PImage的get()方法轻松地获取相机的一小部分(或任何图像),您可以将描述部分矩形(x,y,宽度,高度)的一组坐标传递给该方法。

在计算机视觉中,这也称为感兴趣区域(ROI)。

检索到此区域后,即可对其进行处理。这里是一个最小的例子,展示了如何获得ROI并对其进行处理(在这种情况下,只需根据鼠标位置设置阈值:

代码语言:javascript
复制
import processing.video.*;

Capture cam;
int w = 320;
int h = 240;
int np = w*h;

int roiX = 80;
int roiY = 60;
int roiW = 160;
int roiH = 120;
PImage roi;

void setup(){
  size(w,h);
  cam = new Capture(this,w,h);
  cam.start();
}
void draw(){
  image(cam,0,0);
  if(roi != null){
    //process ROI
//    roi.filter(GRAY);
    roi.filter(THRESHOLD,(float)mouseX/width);
    //display output
    image(roi,roiX,roiY);
  }
}
void captureEvent(Capture c){
  c.read();
  roi = c.get(roiX,roiY,roiW,roiH);
}

您可以使用brightness()函数获取像素的亮度。这意味着您可以通过将每个像素的亮度级别相加,然后将结果除以总像素数来获得ROI的平均亮度:

代码语言:javascript
复制
import processing.video.*;

Capture cam;
int w = 320;
int h = 240;
int np = w*h;

int roiX = 80;
int roiY = 60;
int roiW = 160;
int roiH = 120;
PImage roi;

void setup(){
  size(w,h);fill(127);
  cam = new Capture(this,w,h);
  cam.start();
}
void draw(){
  image(cam,0,0);
  if(roi != null){
    //process ROI
//    roi.filter(GRAY);
    roi.filter(THRESHOLD,(float)mouseX/width);
    //display output
    image(roi,roiX,roiY);
    text("ROI brightness:"+brightness(roi),10,15);
  }
}
void captureEvent(Capture c){
  c.read();
  roi = c.get(roiX,roiY,roiW,roiH);
}
float brightness(PImage in){
  float brightness = 0.0;
  int numPixels = in.pixels.length;
  for(int i = 0 ; i < numPixels; i++) brightness += brightness(in.pixels[i]); 
  return brightness/numPixels; 
}

如果你已经设置了ROI来覆盖明亮的区域,你应该会看到平均亮度随着阴影的出现而下降。只需在条件中使用阈值,就可以对其执行操作:

代码语言:javascript
复制
import processing.video.*;

Capture cam;
int w = 320;
int h = 240;
int np = w*h;

int roiX = 80;
int roiY = 60;
int roiW = 160;
int roiH = 120;
PImage roi;

float brightness = 0.0;
float shadowThresh = 127.0;

void setup(){
  size(w,h);fill(127);
  cam = new Capture(this,w,h);
  cam.start();
}
void draw(){
  image(cam,0,0);
  if(roi != null){
    //process ROI
//    roi.filter(GRAY);
    roi.filter(THRESHOLD,(float)mouseX/width);
    brightness = brightness(roi);
    if(brightness < shadowThresh) println("shadow detected");
    //display output
    image(roi,roiX,roiY);
    text("ROI brightness:"+brightness,10,15);
  }
}
void captureEvent(Capture c){
  c.read();
  roi = c.get(roiX,roiY,roiW,roiH);
}
float brightness(PImage in){
  float brightness = 0.0;
  int numPixels = in.pixels.length;
  for(int i = 0 ; i < numPixels; i++) brightness += brightness(in.pixels[i]); 
  return brightness/numPixels; 
}

希望这些示例易于阅读和理解。请注意,这并不像它们可以做到的那样快。请务必查看处理附带的视频示例(示例>库>视频>捕获),特别是这些示例:BrightnessThresholding、BrightnessTracking

如果您想了解更多关于这些技术的知识,您应该研究一下计算机视觉和OpenCV库。有一个非常好的OpenCV Processing library,你现在可以通过草图>导入库来轻松安装它……> Add Library...,选择OpenCV进行处理。它还附带了使用亮度的示例。

这涵盖了像素操作方面,但进行这种开发的另一个重要方面是设置。有一个可靠的设置是至关重要的:它会让你的生活变得更容易。我的意思是,在你的情况下:

能控制相机的values.

  • having

  • :能够控制自动白平衡/亮度等,因为自动调整可能会使你的values.

  • having失去对场景的控制:确保你减少意外灯光干扰你的跟踪,或者有什么东西撞到你跟踪的相机或物体上的风险。
票数 2
EN

Stack Overflow用户

发布于 2015-08-07 19:17:03

假设您正在分析的相机数据是PImage,您可以对数据应用过滤器,以将其转换为黑白或灰度形式。关于PImage过滤器模式:https://processing.org/reference/filter_.html的文档应该很有用。

你可能需要做像素分析-这里可能有一个库可以帮助你,但你可以从过滤后的PImage中获得一个像素数组,循环遍历它,并根据基准值检查这些值,看看它们是更亮还是更暗。如果它们是0- 255范围内的灰度,如果数字高于基线,则可以区分它们是较亮,还是较暗的数字较低。

票数 0
EN
页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持
原文链接:

https://stackoverflow.com/questions/31867013

复制
相关文章

相似问题

领券
问题归档专栏文章快讯文章归档关键词归档开发者手册归档开发者手册 Section 归档