使用XSLT动态添加HTML标记
使用XSLT动态添加HTML标记
提问于 2015-07-18 20:15:41
我有一个XML文档，其中包含以下内容：
<d1/>
<p1>...</p1>
<p2>...</p2>
<d2/>
<p3>...</p3>
<d3/>其中pn是可能具有子元素和其他内容的元素，dn指示包装p标记的HTML DIV标记应该从哪里开始，但没有相应的结束标记，这仅由下一个dn标记隐式指示。所需的HTML输出如下：
<div>
<p1>...</p1>
<p2>...</p2>
</div>
<div>
<p3>...</p3>
</div>我已经使用以下代码编写了一个XSLT来动态引入<div>和</div>标记：
<xsl:text disable-output-escaping="yes"><div></xsl:text>和
<xsl:text disable-output-escaping="yes"></div></xsl:text>这在Safari上有效，但在FireFox上失败了，这让我怀疑这不是正确的方法。你有没有更好的办法在每个浏览器上都能工作？
在此之前非常感谢。
回答 2
Stack Overflow用户
发布于 2015-07-18 21:59:51
您可以使用一种称为“同级递归”的技术。
给定一个格式良好的输入，例如：
XML
<root>
<d1/>
<p1>a</p1>
<p2>b</p2>
<d2/>
<p3>c</p3>
<d3/>
</root>以下样式表：
XSLT 1.0
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="html"/>
<xsl:template match="/root">
<body>
<xsl:apply-templates select="*[starts-with(name(), 'd')][position()!=last()]"/>
</body>
</xsl:template>
<xsl:template match="*[starts-with(name(), 'd')]">
<div>
<xsl:apply-templates select="following-sibling::*[1][not(starts-with(name(), 'd'))]"/>
</div>
</xsl:template>
<xsl:template match="/root/*[not(starts-with(name(), 'd'))]">
<xsl:copy-of select="."/>
<xsl:apply-templates select="following-sibling::*[1][not(starts-with(name(), 'd'))]"/>
</xsl:template>
</xsl:stylesheet>将返回：
<body>
<div>
<p>a</p>
<p>b</p>
</div>
<div>
<p>c</p>
</div>
</body>Stack Overflow用户
发布于 2015-07-18 22:09:31
Firefox不支持禁用输出转义，因为它不序列化结果树。这个问题是一个分组问题，解决它的一种方法是使用密钥：
<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output indent="yes"/>
<xsl:key name="group" match="body/*[not(starts-with(local-name(), 'd'))]" use="generate-id(preceding-sibling::*[starts-with(local-name(), 'd')][1])"/>
<xsl:template match="body">
<xsl:copy>
<xsl:apply-templates select="*[starts-with(local-name(), 'd')]"/>
</xsl:copy>
</xsl:template>
<xsl:template match="*[starts-with(local-name(), 'd')]">
<div>
<xsl:copy-of select="key('group', generate-id())"/>
</div>
</xsl:template>
</xsl:transform>这将在示例的末尾创建一个空的div，因此您可能希望将最后一个模板更改为
<xsl:template match="*[starts-with(local-name(), 'd')]">
<xsl:if test="key('group', generate-id())">
<div>
<xsl:copy-of select="key('group', generate-id())"/>
</div>
</xsl:if>
</xsl:template>页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持
原文链接：
https://stackoverflow.com/questions/31491052
复制相关文章
相似问题
腾讯云开发者
Copyright © 2013 - 2026 Tencent Cloud. All Rights Reserved. 腾讯云 版权所有
深圳市腾讯计算机系统有限公司 ICP备案/许可证号：粤B2-20090059 
粤公网安备44030502008569号
腾讯云计算（北京）有限责任公司 京ICP证150476号 | 京ICP备11018762号