在方案中将符号添加到两个元素列表的末尾

Question

到目前为止，我已经

(define insert-3
  (lambda (sym ls)
    (cond
      [(null? ls) '()]
      [else (cons sym (insert-3 (caadr ls)))])))

我知道caadr是错误的，因为它不存在于两个元素的列表中。但我不知道如何将符号添加到列表的末尾。

Answer 1

假设

sym is 'c
ls  is '(a b)

那么您的结果将由

> (cons 'a (cons 'b (list 'c)))
'(a b c)

或等效的

> (cons 'a (cons 'b (cons 'c null)))
'(a b c)

因此，您的过程需要对每个元素进行cons操作，直到它消耗了ls，然后是cons (list sym)或(cons sym null)：

(define insert-3 
  (lambda (sym ls) 
    (cond 
      [(null? ls) (list sym)] 
      [else       (cons (car ls) (insert-3 sym (cdr ls)))])))

这样的话

   (insert-3 'c '(a b))
=> (cons 'a (insert-3 'c '(b)))
=> (cons 'a (cons 'b (insert-3 'c '())))
=> (cons 'a (cons 'b (list 'c)))

这将适用于任何长度的列表：

> (insert-3 'c '(a b))
'(a b c)
> (insert-3 'e '(a b c d))
'(a b c d e)

Answer 2

下面是一个非常简单的函数：

(define (insert-3 sym lst)
  (reverse (cons sym (reverse lst))))

这是另一个

(define (insert-3 sym lst)
  (assert (= 2 (length lst)))
  (let ((frst (car  lst))
        (scnd (cadr lst)))
    (list frst scnd sym)))

如果你想开始考虑递归，也要有一点效率：

(define (insert-at-end! sym lst)
  (if (null? lst)
      (list sym)
      (let looking ((l lst))
        (if (null? (cdr l))
            (begin (set-cdr! l (list sym))  ;; replace last `cdr`
                   lst)                     ;; return modified `lst`
            (looking (cdr l))))))
> (insert-at-end! 1 '(5 4 3 2))
(5 4 3 2 1)
> (insert-at-end! 1 '(2))
(2 1)
> (insert-at-end! 1 '())
(1)