XSLT 1.0检查元素是否存在并追加新的子元素

Question

我有以下的source-xml-file，我想用xsl把它转换成另一个xml-file。如何检查某个元素是否存在，并根据此结果创建一个新元素或将一个子元素附加到现有元素？

<Vortriebsorte>
    <Vortriebsort>
        <Name>Südröhre</Name>
        <Bauphase>Kalotte</Bauphase>  
        <Vortrieb>Südröhre</Vortrieb>     
    </Vortriebsort>
    <Vortriebsort>
        <Name>Nordröhre</Name>
        <Bauphase>Strosse</Bauphase>     
        <Vortrieb>Nordröhre</Vortrieb>
    </Vortriebsort>
    <Vortriebsort>
        <Name>Südröhre</Name>
        <Bauphase>Strosse / Sohle</Bauphase>
        <Vortrieb>Südröhre</Vortrieb>
    </Vortriebsort>
</Vortriebsorte>

result-xml-file应该类似于以下代码片段：

<data>
<group name="Abschlagsdaten">
    <group name="Vortrieb: Südröhre">
        <group name="Bauphase: Kalotte">
          <!--- some more stuff -->
        </group>          
        <group name="Bauphase: Strosse / Sohle">
          <!--- some more stuff -->
        </group>
    </group>
    <group name="Vortrieb: Nordröhre">                
        <group name="Bauphase: Strosse / Sohle">
          <!--- some more stuff -->
        </group>
    </group>
</group>
</data>

在result-file中，元素"Bauphase“应该按元素"Vortrieb”分组。我能够在不按"Vortrieb“分组的情况下生成有效的输出。

由于我是xsl-tranformation的新手，如果有人能给我一个提示，如果这是可能的，如果是的话，我将不胜感激。

<?xml version="1.0" encoding="ISO-8859-1"?>
<!-- Edited by XMLSpy® -->
<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:strip-space elements="*" />
<xsl:output method="xml" indent="yes" />

<xsl:template match="@*|node()">            
    <xsl:apply-templates select="@*|node()"/>           
</xsl:template>

<xsl:template match="Vortriebsorte">    
    <data>
        <xsl:for-each select="Vortriebsort">
        <!-- if contains element append new element <group name="Bauphase: ..."> to the existing element -->   
        <xsl:if test="(contains(@name, \"Vortrieb: \"<xsl:value-of select=\"Vortrieb\" />))">
            <group>
                <xsl:attribute name="name">Abschlag: <xsl:value-of select="Bauphase" /> </xsl:attribute>
                <xsl:apply-templates select="Tunnelbandgruppen/Tunnelbandgruppe"/>  
            </group>
            </xsl:if>
        <!-- if NOT contains element add <group name="Vortrieb: ..."> and apply templates for child-nodes -->   
        <xsl:if test="not(contains(@name, \"Vortrieb: \"<xsl:value-of select=\"Vortrieb\" />))">
            <group>
                <xsl:attribute name="name">Vortrieb: <xsl:value-of select="Vortrieb" /> </xsl:attribute>    
                <group>
                    <xsl:attribute name="name">Abschlag: <xsl:value-of select="Bauphase" /> </xsl:attribute>
                    <xsl:apply-templates select="Tunnelbandgruppen/Tunnelbandgruppe"/>  
                </group>
            </group>                
            </xsl:if>-->
        </xsl:for-each>
        </data>
    </tunneltracer-exchange-file>
</xsl:template>

</xsl:stylesheet>

致以亲切的问候，马库斯

Answer 1

您可以尝试使用此模板：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:strip-space elements="*" />
    <xsl:output method="xml" indent="yes" />
    <xsl:template match="/">
        <data>
            <group name="Abschlagsdaten">
                <xsl:apply-templates select="Vortriebsorte/Vortriebsort[not(./Name=preceding::*/Name)]"/>
            </group>
        </data>
    </xsl:template>
    <xsl:template match="Vortriebsort">
        <xsl:variable name="n" select="./Name"/>
        <group>
            <xsl:attribute name="name">
                <xsl:value-of select="'Vortrieb: '"/>
                <xsl:value-of select="./Name"/>
            </xsl:attribute>
            <xsl:apply-templates select="//Bauphase[../Name = $n]"/>
        </group>
    </xsl:template>
    <xsl:template match="Bauphase">
        <group>
            <xsl:attribute name="name">
                <xsl:value-of select="'Bauphase: '"/>
                <xsl:value-of select="."/>
            </xsl:attribute>
        </group>
    </xsl:template>
</xsl:stylesheet>

它将通过Name仅查找不同的Vortriebsort节点，然后搜索与Name具有相同值的所有Bauphase节点。

它将生成以下XML：

<data>
    <group name="Abschlagsdaten">
        <group name="Vortrieb: Südröhre">
            <group name="Bauphase: Kalotte" />
            <group name="Bauphase: Strosse / Sohle" />
        </group>
        <group name="Vortrieb: Nordröhre">
            <group name="Bauphase: Strosse" />
        </group>
    </group>
</data>

Answer 2

您可以在XSLT1.0中使用Muenchian grouping进行分组。

以下是使用该技术生成预期结果样式表：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

    <xsl:output indent="yes"/>

    <xsl:key name="vortrieb-group" match="Vortrieb" use="."/>
    <xsl:key name="bauphase-group" match="Bauphase" use="."/>

    <xsl:template match="Vortriebsorte">
        <data>
            <group name="Abschlagsdaten">
                <xsl:apply-templates/>
            </group>
        </data>
    </xsl:template>

    <xsl:template match="Vortriebsort">
        <xsl:apply-templates select="Vortrieb[generate-id(.)=generate-id(key('vortrieb-group', .))]"/>
    </xsl:template>

    <xsl:template match="Vortrieb">
        <group name="Vortrieb: {.}">
            <xsl:apply-templates select="//Bauphase[../Vortrieb=current()][generate-id(.)=generate-id(key('bauphase-group', .))]"/>
        </group>
    </xsl:template>

    <xsl:template match="Bauphase">
        <group name="Bauphase: {.}">
            <xsl:value-of select="."/>
        </group>
    </xsl:template>

</xsl:stylesheet>