如何在运行XSLT时丢弃XML属性

Question

我有一个XSLT，它可以完美地从现有的XML数据流生成新的XML。但是，根元素列出了几个属性，这些属性在出现时会导致XSLT无法解析数据。

我需要对XSLT进行哪些更改才能使其忽略这些属性？

下面是根元素：

   <CrystalReport xmlns="urn:crystal-reports:schemas:report-detail"  
      xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xsi:schemaLocation="urn:crystal-reports:schemas:report-detail 
      http://www.businessobjects.com/products/xml/CR2008Schema.xsd">

如果只删除属性，XSLT就可以正常运行。如果它们存在，它将忽略整个文件。

您需要查看我的XSLT才能获得帮助吗？

下面是XSLT。(我是否可以修改XSLT以忽略名称空间？)：

<?xml version="1.0"?><!-- DWXMLSource="STX050 Course Descriptions Parsed.xml" -->
<!DOCTYPE xsl:stylesheet>

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="no"/>

<xsl:key name="courses-by-title" match="Details" use="Section/DEPTSDESC1" />

<xsl:template match="CrystalReport">

<crystalreports>
<xsl:for-each select="Details[count(. | key('courses-by-title', Section/DEPTSDESC1)[1]) = 1]">
<xsl:sort select="Section/DEPTSDESC1" />
<department>
<Sectiontitle><xsl:value-of select="Section/DEPTSDESC1"/></Sectiontitle><xsl:text>
</xsl:text>

<xsl:for-each select="key('courses-by-title', Section/DEPTSDESC1)">
<xsl:sort select="Section/DEPTSDESC1" />
<Details> 
<course><xsl:value-of select="Section/DEPTSDESC1"/></course><xsl:text> </xsl:text><courseno><xsl:value-of select="Section/CRSNO1"/></courseno><xsl:text>
</xsl:text><class><xsl:value-of select="Section/CRSTITLE1"/></class><xsl:text>
</xsl:text><classcredit><xsl:value-of select="Section/CRSMINCRED1"/></classcredit><xsl:text> credit hours
</xsl:text><description><xsl:value-of select="Section/CRSDESC1"/></description> 
</Details><xsl:text>
</xsl:text>

</xsl:for-each>
</department>
</xsl:for-each>
</crystalreports>

</xsl:template>


</xsl:stylesheet>

Answer 1

这不是一个属性：

xmlns="urn:crystal-reports:schemas:report-detail"

它是一个命名空间声明。您的XML输入似乎在这个名称空间中，而XSLT从文档中找不到任何东西，这很可能是因为您的所有XPaths都在null名称空间中。您需要做的是在XSLT中声明这个名称空间：

<xsl:stylesheet version="1.0" 
   xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
   xmlns:cr="urn:crystal-reports:schemas:report-detail">

请注意，我已经为它指定了前缀cr。在这种情况下，有必要为名称空间添加一些前缀。

然后，您需要在XPaths中使用相同的前缀：

<xsl:template match="cr:CrystalReports">

...

<xsl:value-of select="cr:SomeNode/cr:AnotherNode" />

诸若此类。

这里的一个问题是，如果XML中的属性在源文档中没有前缀，那么它们就在null名称空间中，并且在引用它们时不应该使用前缀。例如：

如果在同一个XML文档中有一个类似这样元素：

<ReportItem id="5" />

您应该将该属性称为@id，而不是@cr:id

<xsl:apply-templates select="cr:ReportItem[@id = 5]" />