如何从Webspeed URL的名称-值对中删除特殊字符？

Question

我需要删除Webspeed URL中包含名称-值pairs..How的回车和换行符，可以这样做吗？有什么想法请提出来！

Answer 1

要替换字符，可以使用replace函数

REPLACE function
Returns a string with specified substring replacements.
Syntax 
REPLACE ( source-string , from-string , to-string ) 

示例：

DEFINE VARIABLE cTxt    AS CHARACTER   NO-UNDO FORMAT "x(20)".
DEFINE VARIABLE cNewTxt AS CHARACTER   NO-UNDO FORMAT "x(20)".

cTxt = "abc123abc123abc123".

cNewTxt = REPLACE(cTxt, "a", "-").

DISPLAY cNewTxt .

您可以使用控制代码~n确定新行的目标

REPLACE(cString, "~n", "replacing character").

或以个体%0d (十进制ascii代码13)和%0a's (十进制ascii代码10)为目标。

REPLACE(cString, CHR(13), "replacing character").
REPLACE(cString, CHR(10), "replacing character").

Answer 2

我最近需要做一些类似的事情，并发现下面的方法非常方便。这可能有点极端--它删除了所有控制代码和任何高于ascii126的代码。但是您可以很容易地调整这些限制。(我的用途是填充文本字段--所以所有这些内容对我来说都是非法输入。)

define variable hd as character no-undo initial "0123456789ABCDEF".

function hex2char returns character ( h as character ):

  define variable i as integer no-undo.

  if length( h ) <> 2 or index( hd, substring( h, 1, 1 )) < 0 or index( hd, substring( h, 2, 1 )) < 0 then
    return "".

  i = ((( index( hd, substring( h, 1, 1 )) - 1 ) * 16 ) +
          index( hd, substring( h, 2, 1 )) - 1
      ).

  if i < 32 or i >= 127 then
    return "".
   else
    return chr( i ).

end.

function url-decode returns character ( input url as character ):

  define variable xurl as character no-undo.
  define variable zurl as character no-undo.

  define variable pct as integer no-undo.

  /* fix known trouble makers
   */

  assign
    xurl = replace( url, "+", " " )
    xurl = replace( xurl, "%0A%0D", "~n" )      /* <LF><CR>     */
    xurl = replace( xurl, "%0D%0A", "~n" )      /* <CR><LF>     */
    xurl = replace( xurl, "%0D",    "~n" )      /* <CR>         */
  .

  pct  = index( xurl, "%" ).

  do while pct > 0 and xurl > "":
    assign
      zurl = zurl + substring( xurl, 1, pct - 1 ) + hex2char( substring( xurl, pct + 1, 2 ))
      xurl = substring( xurl, pct + 3 )
      pct  = index( xurl, "%" )
    .
  end.

  return zurl + xurl.

end.

display url-decode( sampleUrl ) view-as editor size 60 by 25.