ColdFusion:二进制值的cfqueryparam

Question

我根据此链接querying binary column using like in sql server中提供的帮助编写了以下查询

SELECT * FROM myTable
WHERE TestData >= 0x00010000 
  AND TestData < 0x00020000;

它返回了预期的结果。我使用了cfqueryparam并将查询更新为：

SELECT * FROM myTable
WHERE TestData >= <cfqueryparam value="0x00010000" cfsqltype="cf_sql_binary"> 
  AND TestData < <cfqueryparam value="0x00020000" cfsqltype="cf_sql_binary">;

但它返回了错误，错误消息：Invalid data 0x00010000 for CFSQLTYPE CF_SQL_BINARY.我尝试了cfsqltype="CF_SQL_BLOB"，但没有结果。如何解决此问题？提前感谢

Answer 1

按照现在的情况，保持查询为没有任何错误：

SELECT * FROM myTable
WHERE TestData >= 0x00010000 AND TestData < 0x00020000

(理想情况下，您应该列出单个列，而不是使用*。)

然而，虽然参数化这些查询没有安全上的好处(它们没有变量，因此不容易SQL注入)，但为了缓存单个执行计划，使用参数化的SQL可能仍然有好处。

如果您有多个查询，格式为：

<cfquery...>
    SELECT * FROM myTable
    WHERE TestData >= 0x00010000 AND TestData < 0x00020000
</cfquery>

<cfquery...>
    SELECT * FROM myTable
    WHERE TestData >= 0x00020000 AND TestData < 0x00030000
</cfquery>

<cfquery...>
    SELECT * FROM myTable
    WHERE TestData >= 0x00030000 AND TestData < 0x00040000
</cfquery>

对这些使用cfqueryparam将允许为多个查询缓存单个执行计划，从而潜在地带来更好的性能。

在这种情况下，您需要使用BinaryDecode将十六进制字符串转换为cfqueryparam可以处理的二进制值，如下所示：

<cfquery...>
    SELECT * FROM myTable
    WHERE TestData >= <cfqueryparam value=#BinaryDecode('00010000','Hex')# cfsqltype="cf_sql_binary" />
    AND   TestData <  <cfqueryparam value=#BinaryDecode('00020000','Hex')# cfsqltype="cf_sql_binary" />
</cfquery>

(请注意，省略了0x前缀。)