如何在黑莓10级联中创建具有我选择的背景色的按钮？

Question

我想创建一个按钮的背景色在黑莓10级联我的选择。

我该怎么做呢？

Answer 1

创建自己的按钮非常简单，只要你习惯了qml :)

下面是一个自定义按钮的示例，将其放在一个文件中，如CustomButton.qml。您还可以使用属性来传递颜色，使其易于重用。

Container {
    property alias text: label.text

    signal clicked()  //emits a clicked signal.
        gestureHandlers: [
        TapHandler {
                onTapped: {
                    clicked();
            }
        }
    ]

    layout: DockLayout {
    }

    Container {
        background: Color.Red
        horizontalAlignment: HorizontalAlignment.Fill
        Container {
            horizontalAlignment: HorizontalAlignment.Center
            verticalAlignment: VerticalAlignment.Center
            topPadding: 10
            bottomPadding: 15
            leftPadding: 20
            rightPadding: 20
            Label {
                id: label
                text: "demo"
                textStyle {
                    base: tsLabel.style
                }
                topMargin: 0
                bottomMargin: 0
                topPadding: 0
                bottomPadding: 0
            }
        }
    }

    attachedObjects: [
        TextStyleDefinition {
            id: tsLabel
            base: SystemDefaults.TextStyles.BodyText
            fontSize: FontSize.Small
            color: Color.White
            fontWeight: FontWeight.W100
        }
    ]
}

要在主页中使用它，您只需执行以下操作：

CustomButton {
    text: "my button"
    onClicked: {
        //do code
    }
}

要增强这一点，您可以在onTapped函数中添加动画或颜色更改。您还可以使用9patch作为按钮图像，使用imagePaint而不是Color.Red。