批处理文件播放列表随机排序

Question

我已经做了一个小的批处理文件程序来创建一个播放列表

@echo off
DIR /S /o:n /b *.avi > Playlist.m3u

有没有办法改变这一点，让它在每次运行时都按随机顺序排序？

Answer 1

这是可以做到的，但它不会很漂亮！你能使用更好的平台而不是批处理文件吗？也许这正是你期待已久的学习Powershell的机会！:-)

但是，如果您坚持使用批处理，以下是我尝试的一般方法：

1. 计算文件夹中的.avi文件数。
2. 在0和此数字之间随机选择一个数字。例如，set /a randomLineNum=%random% %% 10会将% echo %%L > Playlist.m3u.
3. Go LineNum%设置为0到9之间的数字。
4. 使用类似for /f "skip=%randomLineNum%" %%L in ('dir /s /o:n /b *.avi') ...的命令来获取随机行，并将其返回到#2。

这种简单化的方法最终会得到重复的结果，而我并没有以任何方式构建来退出循环。我将这些问题留给您来解决(或者在将来的问题中提出)。:-)

Answer 2

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
::
:: establish a tempfile name
::
:temploop
SET tempfile="%temp%\temp%random%.tmp"
IF EXIST %tempfile% GOTO temploop
::
:: Write the list of filenames with each
:: prefixed by a random number and a colon
::
(FOR /f "delims=" %%i IN (
  'dir /s/b *.avi'
 ) DO ECHO !random!:%%i
)>%tempfile% 
::
:: Write the playlist.
:: sort the tempfile (which places it 
:: in random order) and remove the number:
::
(FOR /f "tokens=1*delims=:" %%i IN (
  ' sort ^<%tempfile% ') DO ECHO %%j
) >playlist.m3u
::
:: and delete the tempfile.
::
DEL %tempfile% 2>NUL

应该可以工作-但如果您的文件/路径名包含!，则it 将会有困难

代码中的文档。

Answer 3

没有临时文件的解决方案：

@echo off &setlocal
set "playlist=Playlist.m3u"
del %playlist% 2>nul
set /a files=0
for %%i in (*.avi) do set /a files+=1
if %files% equ 0 (echo No AVI found&goto:eof) else echo %files% AVI's found.
set /a cnt=%files%-1
for /l %%i in (0,1,%cnt%) do for /f "delims=" %%a in ('dir /b /a-d *.avi^|more +%%i') do if not defined $avi%%i set "$avi%%i=%%a"
:randomloop
set /a rd=%random%%%%files%
call set "avi=%%$avi%rd%%%"
if not defined avi goto :randomloop
set "$avi%rd%="
>>%playlist% echo %avi%
set /a cnt-=1
if %cnt% geq 0 goto:randomloop
echo Done!
endlocal

它不使用DelayedExpansion，因此它可以处理名称中带有感叹号的文件。这需要更多的时间，但也不需要临时文件。