首页
学习
活动
专区
圈层
工具
发布
社区首页 >问答首页 >数组函数:如何在日期范围内求和?

问数组函数:如何在日期范围内求和?
EN

Stack Overflow用户
提问于 2012-10-10 17:51:06
回答 2查看 1K关注 0票数 0

我们有一个相当复杂的数组问题,我们正在努力克服:

这是我们用来根据满足的单个参数对不同列求和的标准数组公式,在本例中,值$k$6在F列内。

代码语言:javascript
复制
=SUM(('EVERYTHING PIVOT'!$F$5:$F$100000=$K$6)*('EVERYTHING PIVOT'!$K$5:$K$100000))

但是,我们现在希望将该日期组的值相加,该日期组比该范围内的最新日期早30天。

日期列A中的值将满足此条件:

代码语言:javascript
复制
">"&MAX($A$5:$A$100000)-30

但是,我看不到将其作为附加参数集成到第一个数组公式中的方法,因为数组公式只能使用单个值,而不能使用范围。

我是不是遗漏了什么?

EN

回答 2

Stack Overflow用户

发布于 2012-10-10 18:11:17

你会更好地使用这样的SUMIF作为你的原始版本,即

=SUMIF('EVERYTHING PIVOT'!$F$5:$F$100000,$K$6,'EVERYTHING PIVOT'!$K$5:$K$100000)

如果您有Excel2007或更高版本(假设您有,否则不能使用100,000行),则可以在SUMIFS函数中添加一个条件,即

=SUMIFS('EVERYTHING PIVOT'!$K$5:$K$100000,'EVERYTHING PIVOT'!$F$5:$F$100000,$K$6,'EVERYTHING PIVOT'!$A$5:$A$100000,">"&MAX($A$5:$A$100000)-30)

注意SUMIFS的语法是不同的,sum范围在开头

在旧版本的excel中,可以像这样修改数组公式。

=SUM(('EVERYTHING PIVOT'!$F$5:$F$100000=$K$6)*('EVERYTHING PIVOT'!$K$5:$K$100000)*('EVERYTHING PIVOT'!$A$5:$A$100000>MAX($A$5:$A$100000)-30 ))

票数 1
EN

Stack Overflow用户

发布于 2012-10-10 18:11:48

如果您使用的是Excel2007或更高版本,请考虑使用SUMIFS

代码语言:javascript
复制
=SUMIFS('EVERYTHING PIVOT'!$K:$K,
        'EVERYTHING PIVOT'!$F:$F,$K$6,
        'EVERYTHING PIVOT'!$A:$A,">"&MAX('EVERYTHING PIVOT'!$A:$A)-30)

SUMIFS将单元格添加到满足多个条件的区域中

代码语言:javascript
复制
SUMIFS(sum_range, criteria_range1, criteria1, [criteria_range2, criteria2], ...)

如果使用excel 2003或更早版本,则可以使用SUMPRODUCT执行类似的操作。

票数 1
EN
页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持
原文链接:

https://stackoverflow.com/questions/12816487

复制
相关文章

相似问题

领券
问题归档专栏文章快讯文章归档关键词归档开发者手册归档开发者手册 Section 归档