函数返回类型不匹配

Question

我正在尝试用Fortran重新编码一个旧的C++程序，以利用LAPACK (我知道C++确实有LAPACK++，但我在安装它时遇到了很多问题，所以我放弃了)。

我最初在编译方面没有任何问题，但那是因为我将所有变量都声明为REAL。当我开始编写需要LAPACK的程序部分时，我发现传递给DSYEV的所有参数都需要为DOUBLE PRECISION。因此，我尝试将所有内容更改为双精度(包括将所有硬编码数字更改为对应的双精度，即0.0 -> 0.0D0)。现在，当我尝试编译时，所有函数和子例程都会出现以下错误：

    Error: Return type mismatch of function <function> at (1) (REAL(4)/REAL(8))

我不确定这是从哪里来的，因为程序中的所有内容都被更改为双精度。

例如，我声明了以下内容：

double precision :: alpha(3),d(3),zeta1,zeta2
double precision :: A1(3),A2(3),D1(3),D2(3)
double precision :: PI
PI = 3.14159265359D0
alpha = (/0.109818D0, 0.405771D0, 2.22766D0/)
d = (/0.444635D0, 0.535328D0, 0.154329D0 /)

do 10 i=1,3

A1(i) = alpha(i)*zeta1**2.0D0
A2(i) = alpha(i)*zeta2**2.0D0
D1(i) = d(i)*(2.0D0*A1(i)/PI)**(3.0D0/4.0D0)
D2(i) = d(i)*(2.0D0*A2(i)/PI)**(3.0D0/4.0D0)

10  continue

和函数：

subroutine createS(S,A1,A2,D1,D2,r)
double precision A1(3),A2(3),D1(3),D2(3) 
double precision r
double precision S(2,2)
integer :: i,j
S(1,1) = 1.0D0
S(2,2) = 1.0D0
do 80 i=1,3
do 90 j=1,3

S(1,2) = S(1,2) + getS(A1(i),A2(j),r)*D1(i)*D2(j)

 90 continue
 80 continue
S(2,1) = S(1,2)
return
end

double precision function getS(a,b,r)
double precision :: PI
double precision a,b,r
double precision :: S
PI = 3.14159265359D0
S = (PI/(a+b))**1.5D0
S = S*dexp(-(a*b*r*r)/(a+b))
getS = S
return
end

然后我得到了错误

  HFSTO3G.f:85.28:

  S(1,2) = S(1,2) + getS(A1(i),A2(j),r)*D1(i)*D2(j)                 
                        1
  Error: Return type mismatch of function 'gets' at (1) (REAL(4)/REAL(8))

我正在使用gfortran进行编译。这可能是问题所在吗？我不是编程新手，但我是Fortran新手。不能在Fortran中对此进行编程。

Answer 1

你有没有将子例程和函数放到一个模块中并对该模块执行use操作？否则，可能发生的情况是，您在子例程createS中将getS隐式类型化为单精度实数，但它实际上返回了双精度。另一个建议:始终使用implicit none来查找未声明的变量。如果您忘记在源代码中包含implicit none，gfortran提供了编译器选项-fimplicit-none。隐式类型是有害的，可能会在Fortran中继续使用以支持遗留代码。

P.S. double precision也是过时的，但比隐式类型风险小得多。如果您使用的是gfortran的最新版本，则可以使用以下命令：

use ISO_FORTRAN_ENV
real (real64) ::

请参阅gfortran手册。

编辑：implicit none将getS的类型从real(4) (通过隐式类型)更改为unknown (未声明类型，禁用隐式类型)。如果您将过程放入一个模块中，它们将“知道”彼此的类型:函数返回和参数类型。这将修复此错误。它还可以帮助编译器找到其他错误，但使其能够检查调用和过程参数之间的参数一致性。有关示例，请参阅Correct use of modules, subroutines and functions in fortran和Computing the cross product of two vectors in Fortran 90。

Answer 2

您没有在子例程createS中将getS声明为函数。您需要在子例程createS的变量声明中添加double precision, external :: getS。