首页
学习
活动
专区
圈层
工具
发布
社区首页 >问答首页 >用于将文件从本地目录移动到特定ftp位置的批处理脚本

问用于将文件从本地目录移动到特定ftp位置的批处理脚本
EN

Stack Overflow用户
提问于 2011-07-30 16:52:21
回答 1查看 7.1K关注 0票数 2

目前我有一个批处理脚本,它备份我的数据库并将备份文件存储在特定的本地目录中,例如,C:\ backups \ backup -30-07-2011.bak (备份文件将使用当前日期创建)。

现在,我需要一个批处理脚本,只移动备份文件是在当前日期创建到FTP位置。因此,我的批处理脚本必须:(1)使用用户名和密码连接到ftp站点(2)将当前日期的文件移动到指定的ftp位置。有没有人能帮我写这个批处理脚本。

谢谢..

EN

回答 1

Stack Overflow用户

发布于 2011-07-31 18:43:42

有关ftp的更多信息,请单击此处:http://www.nsftools.com/tips/MSFTP.htm批处理脚本示例,它会制作备份的副本:

代码语言:javascript
复制
@echo off
    :: Set filename and path
    :: %date:.=-% mean replace dots '.' to '-' in the variable's value  (31.07.2011)
    :: More info: set /?
    set "fileName=backup-%date:.=-%.bak"
    :: There mustn't be slash in end. "C:\Backups\" is wrong, "C:\Backups" is right
    set "filePath=C:\Backups"
    set "ftpFilePath=somepath"

    :: there must be ftp's IP & port
    set "ftpIP=127.0.0.1"
    set "ftpPort=21"

    :: replace with your own username & password
    set "username=username"
    set "password=password"

    :: Write commands in file
    :: Open server
    echo o %ftpIP% %ftpPort%>ftpcmds
    :: Say your name & password. If you have no password - just do not change   these lines
    echo %username%>>ftpcmds
    echo %password%>>ftpcmds
    :: We send binary data, yep?
    echo binary>>ftpcmds
    :: Change ftp path
    echo cd %ftpFilePath%>>ftpcmds
    :: Change local path
    echo lcd "%filePath%">>ftpcmds
    :: Yeah, we can send file
    echo send %fileName%>>ftpcmds
    :: Bye = disconnect + quit
    echo bye>>ftpcmds

    :: Run ftp-client. More info: ftp --help
    :: Delete '>nul' if you want see output of ftp
    ftp -s:ftpcmds>nul
exit /b

如果你愿意,你可以添加删除原始文件的命令(把它放在'exit /b‘之前):

代码语言:javascript
复制
del /s/q %filePath%\%fileName%>nul
票数 1
EN
页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持
原文链接:

https://stackoverflow.com/questions/6882101

复制
相关文章

相似问题

领券
问题归档专栏文章快讯文章归档关键词归档开发者手册归档开发者手册 Section 归档