我正在Excel中做一些VBA编程,并且有一个工作簿,其中所有的数据表都要复制到另一个工作表中。新的工作表将有几个标题行,我希望跟踪它们的位置,这样我就不必不断地在其中查找单词。
当Excel工作簿打开时,使用类并使其保持运行是最简单的事情吗?或者这会使它变得笨重和难以处理,而我应该继续使用子例程?使用类的好处是什么?这不像我有几个对象,只有表和列上的验证。
发布于 2010-01-30 02:08:32
使用类而不仅仅是子例程的优点是,类创建了一个抽象级别,允许您编写更干净的代码。诚然,如果您以前从未在VBA中使用过类,那么有一个学习曲线,但我相信这是值得花时间弄清楚的。
应该切换到类的一个关键指示是,如果您经常向函数和子例程添加参数。在这种情况下,最好总是使用类。
我从one of my previous Stack Overflow answers复制了一个类的解释
这里有一个很长的示例,说明使用类可能会对您有所帮助。虽然这个示例很长,但它将向您展示面向对象编程的一些原则如何真正帮助您清理代码。
在VBA编辑器中,转到Insert > Class Module。在“属性”窗口(默认情况下位于屏幕的左下角)中,将模块的名称更改为WorkLogItem。将以下代码添加到类中:
Option Explicit
Private pTaskID As Long
Private pPersonName As String
Private pHoursWorked As Double
Public Property Get TaskID() As Long
TaskID = pTaskID
End Property
Public Property Let TaskID(lTaskID As Long)
pTaskID = lTaskID
End Property
Public Property Get PersonName() As String
PersonName = pPersonName
End Property
Public Property Let PersonName(lPersonName As String)
pPersonName = lPersonName
End Property
Public Property Get HoursWorked() As Double
HoursWorked = pHoursWorked
End Property
Public Property Let HoursWorked(lHoursWorked As Double)
pHoursWorked = lHoursWorked
End Property上面的代码将为我们提供一个特定于我们正在处理的数据的强类型对象。当您使用多维数组存储数据时,您的代码类似于:arr(1,1)是ID,arr(1,2)是PersonName,arr(1,3)是HoursWorked。使用这种语法,很难知道什么是什么。让我们假设您仍然将对象加载到数组中,但使用的是我们上面创建的WorkLogItem。这个名字,你可以做arr(1).PersonName来得到这个人的名字。这会使你的代码更容易阅读。
让我们继续这个例子。我们将尝试使用collection,而不是将对象存储在数组中。
接下来,添加一个新的类模块,并将其命名为ProcessWorkLog。将以下代码放入其中:
Option Explicit
Private pWorkLogItems As Collection
Public Property Get WorkLogItems() As Collection
Set WorkLogItems = pWorkLogItems
End Property
Public Property Set WorkLogItems(lWorkLogItem As Collection)
Set pWorkLogItems = lWorkLogItem
End Property
Function GetHoursWorked(strPersonName As String) As Double
On Error GoTo Handle_Errors
Dim wli As WorkLogItem
Dim doubleTotal As Double
doubleTotal = 0
For Each wli In WorkLogItems
If strPersonName = wli.PersonName Then
doubleTotal = doubleTotal + wli.HoursWorked
End If
Next wli
Exit_Here:
GetHoursWorked = doubleTotal
Exit Function
Handle_Errors:
'You will probably want to catch the error that will '
'occur if WorkLogItems has not been set '
Resume Exit_Here
End Function上面的类将用于对一组WorkLogItem“做一些事情”。最初,我们只是将其设置为计算总工作小时数。让我们测试一下我们编写的代码。创建一个新的模块(这次不是类模块;只是一个“常规”模块)。将以下代码粘贴到模块中:
Option Explicit
Function PopulateArray() As Collection
Dim clnWlis As Collection
Dim wli As WorkLogItem
'Put some data in the collection'
Set clnWlis = New Collection
Set wli = New WorkLogItem
wli.TaskID = 1
wli.PersonName = "Fred"
wli.HoursWorked = 4.5
clnWlis.Add wli
Set wli = New WorkLogItem
wli.TaskID = 2
wli.PersonName = "Sally"
wli.HoursWorked = 3
clnWlis.Add wli
Set wli = New WorkLogItem
wli.TaskID = 3
wli.PersonName = "Fred"
wli.HoursWorked = 2.5
clnWlis.Add wli
Set PopulateArray = clnWlis
End Function
Sub TestGetHoursWorked()
Dim pwl As ProcessWorkLog
Dim arrWli() As WorkLogItem
Set pwl = New ProcessWorkLog
Set pwl.WorkLogItems = PopulateArray()
Debug.Print pwl.GetHoursWorked("Fred")
End Sub在上面的代码中,PopulateArray()只是创建了一个WorkLogItem集合。在实际代码中,可以创建类来解析Excel表或数据对象,以填充集合或数组。
TestGetHoursWorked()代码简单地演示了如何使用这些类。您会注意到ProcessWorkLog被实例化为一个对象。实例化后,WorkLogItem的集合成为pwl对象的一部分。您可以在Set pwl.WorkLogItems = PopulateArray()行中注意到这一点。接下来,我们只需调用我们编写的函数,该函数作用于集合WorkLogItems。
为什么这是有帮助的?
假设您的数据发生了变化,并且您想要添加一个新方法。假设您的WorkLogItem现在包含一个用于HoursOnBreak的字段,并且您想要添加一个新方法来计算该值。
您所需要做的就是向WorkLogItem添加一个属性,如下所示:
Private pHoursOnBreak As Double
Public Property Get HoursOnBreak() As Double
HoursOnBreak = pHoursOnBreak
End Property
Public Property Let HoursOnBreak(lHoursOnBreak As Double)
pHoursOnBreak = lHoursOnBreak
End Property当然,您需要更改填充集合的方法(我使用的示例方法是PopulateArray(),但您可能应该为此使用一个单独的类)。然后,只需将新方法添加到ProcessWorkLog类:
Function GetHoursOnBreak(strPersonName As String) As Double
'Code to get hours on break
End Function现在,如果我们想要更新我们的TestGetHoursWorked()方法以返回GetHoursOnBreak的结果,我们所要做的就是添加以下行:
Debug.Print pwl.GetHoursOnBreak("Fred")如果传入了表示数据的值数组,则必须在代码中查找使用数组的每个位置,然后对其进行相应更新。如果改为使用类(以及它们的实例化对象),则可以更轻松地更新代码以处理更改。此外,当您允许以多种方式使用类时(可能一个函数只需要4个对象属性,而另一个函数需要6个),它们仍然可以引用同一个对象。这使您不必为不同类型的函数使用多个数组。
为了进一步阅读,我强烈建议您购买一份VBA Developer's Handbook, 2nd edition。这本书充满了很好的例子和最佳实践,以及大量的示例代码。如果你为一个严肃的项目在VBA上投入了大量的时间,那么值得你花时间阅读这本书。
发布于 2010-01-30 01:24:44
如果有很多子例程,或者子例程非常长,那么将代码结构化到类中可能会有所帮助。如果只有几个子例程,每个子例程只有10行代码,那么这就结束了。将代码结构化到类中的好处是,当您返回到它时,它更容易阅读和更改。因此,将代码结构化为类的另一个原因是,如果代码可能需要向下更改
发布于 2014-01-14 02:17:44
除了其他贡献者所说的优点之外,你还可以添加另一件事(很抱歉,如果它在Ben McCormack的精彩答案中的某个地方,而我错过了它)。如果您的VBA脚本可能在某一时刻被重新编程,则类可能会有所用处。
例如,我正在设计一种订单管理系统。它将被几个同事使用很长一段时间,但如果排序规则发生变化,它可能需要重新编程。因此,我设计了一个基本的股票项目类,它收集有关股票项目的所有信息。然而,关于如何为任何订单分析这些数据的规则是在易于访问和注释良好的子例程中编写的。通过这样做,我希望未来的VBA程序员可以轻松地更改生成订单的数学规则,而不必处理如何收集有关特定库存项目的所有数据(这都是由类中的子例程和函数完成的,这些子例程和函数在向类传递库存编号时被激活)。类的公共属性也被intellisense拾取,允许下一位程序员以及您自己更轻松地使用它。
我想重点是,如果类编码了一些基本的信息集,或者一些概念性的对象,这些信息总是可能与程序的使用上下文相关,那么类可以通过这种方式使以后的用户的工作更容易。
https://stackoverflow.com/questions/2161666
复制相似问题